# Maintainer: Luke Shumaker <lukeshu@sbcglobal.net>

pkgname=smartdashboard-extension-wpicameraextension
pkgver=210
pkgrel=1
pkgdesc="WPI Camera Extension for SmartDashboard"
arch=('any')
groups=(frc)
url="http://firstforge.wpi.edu/sf/projects/smartdashboard"
license=unknown
depends=(smartdashboard-client wpijavacv)
makedepends=(apache-ant netbeans)
source=("https://gitorious.org/absfrc/sources/blobs/raw/master/$pkgname-$pkgver-$pkgrel-any.src.tar.xz")

build() {
  cd "$srcdir"
  cp -a /usr/share/smartdashboard/src SmartDashboard
  cp -a /usr/share/java/wpilibj/NetworkTable_Client .
  cp -a /usr/share/java/WPIJavaCV .
  sed -i \
    -e 's@^\(project\.NetworkTable_Client=\).*@\1../NetworkTable_Client@' \
    SmartDashboard/nbproject/project.properties

  cd "$pkgname"
  sed -i \
    -e 's@^\(project\.SmartDashboard=\).*@\1../SmartDashboard@' \
    -e 's@^\(project\.WPIJavaCV=\).*@\1../WPIJavaCV@' \
    nbproject/project.properties

  ant jar
}

package() {
  install -d "$pkgdir/usr/share/smartdashboard/extensions/lib"
  cd "$pkgdir/usr/share/smartdashboard/extensions"
  install -m644 "$srcdir/$pkgname/dist/WPICameraExtension.jar" .
  ln -s /usr/share/java/WPIJavaCV.jar lib
  ln -s /usr/share/java/javacpp.jar lib
  ln -s /usr/share/java/javacv.jar lib
  ln -s /usr/share/java/javacv-platform.jar lib
}

md5sums=('77c841a9e86c5197b5583717ce730f42')