2 files changed, 94 insertions, 0 deletions
diff --git a/pcr/libixp-hg/PKGBUILD b/pcr/libixp-hg/PKGBUILD
new file mode 100644
index 000000000..3642535d1
--- /dev/null
+++ b/pcr/libixp-hg/PKGBUILD
@@ -0,0 +1,38 @@
+# Maintainer: Luke Shumaker <lukeshu@sbcglobal.net>
+
+pkgname="libixp-hg"
+pkgver=148
+pkgdesc="A 9p client/server library"
+url="http://libs.suckless.org/libixp"
+license=("MIT")
+
+provides=("libixp")
+conflicts=("libixp")
+
+pkgrel=1
+arch=("i686" "x86_64")
+makedepends=("txt2tags")
+options=(staticlibs)
+
+source=("libre://${pkgname}-${pkgver}.tar.gz")
+md5sums=('5a2fd075108558b39988610d2bb184d9')
+
+mkdepends=("mercurial")
+mksource=("$pkgname-$pkgver::hg+https://code.google.com/p/libixp/#revision=${pkgver}")
+mkmd5sums=('SKIP')
+mksource() {
+	# don't include this precompiled binary (probably included by accident)
+	rm "${srcdir}/${pkgname}-${pkgver}/test/o.client"
+}
+
+_makeflags=("PREFIX=/usr" "ETC=/etc")
+build() {
+	cd "$srcdir/$pkgname-$pkgver"
+	make "${_makeflags[@]}"
+}
+
+package() {
+	cd "$srcdir/$pkgname-$pkgver"
+	make "${_makeflags[@]}" DESTDIR="$pkgdir" install
+	install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
diff --git a/pcr/wmii-hg/PKGBUILD b/pcr/wmii-hg/PKGBUILD
new file mode 100644
index 000000000..c556a1b88
--- /dev/null
+++ b/pcr/wmii-hg/PKGBUILD
@@ -0,0 +1,56 @@
+# Maintainer: Luke Shumaker <lukeshu@sbcglobal.net>
+
+# Maintainer (AUR): N30N <archlinux@alunamation.com>
+# Contributor: Anthony Martin <ality@pbrane.org>
+# Contributer: thomasd <thdahms@gmx.de>
+# Contributer: karnath <karnath@pop3.ru>
+# Contributer: MrBougo <bougospam@gmail.com>
+# Contributor: Wolf Ramovsky <wolf.ramovsky@gmail.com>
+
+pkgname=wmii-hg
+pkgver=2813
+pkgdesc="A small, dynamic window manager for X11"
+url="https://code.google.com/p/wmii/"
+license=("MIT")
+
+provides=("wmii")
+conflicts=("wmii")
+
+pkgrel=1
+arch=("i686" "x86_64")
+depends=('libxft' 'libxrandr' 'libxinerama')
+makedepends=('txt2tags' 'libixp') # libixp is statically linked
+
+source=("libre://${pkgname}-${pkgver}.tar.gz")
+md5sums=('74eb9f91000321b587e7826be999d4de')
+
+mkdepends=('mercurial')
+mksource=("$pkgname-$pkgver::hg+https://code.google.com/p/wmii/#revision=${pkgver}")
+mkmd5sums=('SKIP')
+mksource() {
+	# don't include this precompiled binary (probably included by accident)
+	rm "${srcdir}/${pkgname}-${pkgver}/lib/libutf/libutf.a"
+}
+
+build() {
+	cd "$srcdir/$pkgname-$pkgver"
+
+	export LDFLAGS+=',--no-as-needed'
+	sed -i 's|PREFIX = /usr/local|PREFIX = /usr|' config.mk
+	sed -i 's|ETC = $(PREFIX)/etc|ETC = /etc|' config.mk
+	sed -i 's|PYTHON = .*|PYTHON = python2|' config.mk
+	echo 'CFLAGS += -O2' >> config.mk
+	sed -i 's# !=#!=#' mk/hdr.mk
+
+	export MAKEFLAGS="-j1"
+	make
+}
+
+package() {
+	cd "$srcdir/$pkgname-$pkgver"
+	make DESTDIR="$pkgdir" install
+
+	install -Dm644 img/wmii.png "${pkgdir}"/usr/share/pixmaps/wmii.png
+	install -Dm644 debian/file/wmii.desktop "${pkgdir}"/usr/share/xsessions/wmii.desktop
+	install -Dm644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
+}