From 8c9d16dca525b75bd33b368ff24e1f469db6157a Mon Sep 17 00:00:00 2001
From: "coadde [Márcio Alexandre Silva Delgado]" <coadde@parabola.nu>
Date: Mon, 22 Aug 2016 22:55:48 -0300
Subject: add loggerhead-bzr to [pcr]

---
 pcr/loggerhead-bzr/PKGBUILD | 37 +++++++++++++++++++++++++++++++++++++
 1 file changed, 37 insertions(+)
 create mode 100644 pcr/loggerhead-bzr/PKGBUILD

diff --git a/pcr/loggerhead-bzr/PKGBUILD b/pcr/loggerhead-bzr/PKGBUILD
new file mode 100644
index 000000000..6c10a7c34
--- /dev/null
+++ b/pcr/loggerhead-bzr/PKGBUILD
@@ -0,0 +1,37 @@
+# Maintainer: Márcio Silva <coadde@parabola.nu>
+
+_pkgname=loggerhead
+pkgname=$_pkgname-bzr
+_pkgrev=490
+pkgver=r$_pkgrev
+pkgrel=1
+pkgdesc='The Web viewer for projects in GNU Bazaar'
+arch=('i686' 'x86_64' 'armv7h')
+license=('GPL2')
+depends=('bzr' 'python2-simpletal' 'python2-simplejson' 'python2-paste')
+optdepends=('python2-pastedeploy: for proxying through web server software'
+            'python2-flup: needs to use FastCGI, SCGI or AJP')
+makedepends=('python2-setuptools')
+provides=("$_pkgname")
+conflicts=("$_pkgname")
+url="https://launchpad.net/$_pkgname"
+source=("$pkgname-$pkgver::bzr+$url#revision=$_pkgrev")
+sha512sums=('SKIP')
+
+prepare() {
+  cd $srcdir/$pkgname-$pkgver
+  sed -i 's|env python|env python2|' {info.py,serve-branches}
+  sed -i 's|/python|/python2|' $_pkgname.wsgi
+}
+
+build() {
+  cd $srcdir/$pkgname-$pkgver
+  python2 setup.py build
+}
+
+package() {
+  cd $srcdir/$pkgname-$pkgver
+  python2 setup.py install --root=$pkgdir
+  mv -v $pkgdir/usr/share/{doc,webapps}
+  mv -v $pkgdir/usr/{bin/$_pkgname.wsgi,share/webapps/$_pkgname}
+}
-- 
cgit v1.2.3-54-g00ecf