# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: Márcio Silva <coadde@parabola.nu>

pkgbase=mesa
_pkgname=libcl
pkgname=lib32-$pkgbase-$_pkgname
pkgver=10.3.0
pkgrel=3
pkgdesc='Mesa 3-D OpenCL library and ICD loader (32-bit)'
arch=('x86_64')
url="http://${pkgbase}3d.sourceforge.net"
license=('custom')
depends=("$pkgbase-$_pkgname" "lib32-$pkgbase" 'lib32-libclc' 'lib32-clang')
# please use libretools, install "multilib-devel" on chroot and add
#  "CHROOTEXTRAPKG=(multilib-devel)" on "/etc/libretools.d/chroot.conf" file.
makedepends=('dri2proto' 'dri3proto' 'glproto' 'presentproto' 'python2')
provides=("lib32-$_pkgname")
conflicts=("lib32-$_pkgname" "lib32-$_pkgname-libre" 'lib32-opencl-nvidia' 'lib32-opencl-nvidia-304xx')
replaces=("lib32-$_pkgname" "lib32-$_pkgname-libre" 'lib32-opencl-nvidia' 'lib32-opencl-nvidia-304xx')
source=("ftp://ftp.freedesktop.org/pub/$pkgbase/${pkgver%.0}/${pkgbase^}Lib-$pkgver.tar.bz2")
sha512sums=('c5edc62dcd953b67307cd8a10921ad3f07bd72cdb81ca69f68706a757fd6c5e439f05f546e401e0b5e6923e0decdf34f0b48dcc1d8a758508a7f8fedb734442c')

build() {
  cd $srcdir/${pkgbase^}-$pkgver

  export CC="gcc -m32"
  export CXX="g++ -m32"
  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
  export LLVM_CONFIG=/usr/bin/llvm-config32

  autoreconf -vfi # our automake is far too new for their build system :)

  ./configure --prefix=/usr --libdir=/usr/lib32 --enable-32-bit \
    --sysconfdir=/etc \
    --enable-llvm-shared-libs \
    --enable-opencl \
    --with-clang-libdir=/usr/lib32
  make

  # fake installation
  mkdir $srcdir/fakeinstall
  make DESTDIR=$srcdir/fakeinstall install
}

package() {
  cd $srcdir/${pkgbase^}-$pkgver

  install -vm755 -d $pkgdir/usr/lib32/
  mv -v $srcdir/fakeinstall/usr/lib32/libOpenCL* $pkgdir/usr/lib32/

  install -vm755 -d $pkgdir/usr/share/licenses/$pkgname
  install -vm644 docs/COPYING      $pkgdir/usr/share/licenses/$pkgname
  install -vm644 docs/license.html $pkgdir/usr/share/licenses/$pkgname/LICENSE
}

# vim:set ts=2 sw=2 et: