# U-Boot: BeagleBoard and BeagleBoard-xM
# Maintainer: André Silva <emulatorman@parabola.nu>

buildarch=4

pkgname=uboot4extlinux-omap3_beagle
pkgver=2016.01
pkgrel=3
pkgdesc="U-Boot with Extlinux support for BeagleBoard and BeagleBoard-xM"
arch=('armv7h')
url="http://git.denx.de/u-boot.git/"
license=('GPL')
conflicts=('uboot-omap3_beagle' 'uboot4grub-omap3_beagle')
makedepends=('bc')
backup=(boot/extlinux/extlinux.conf)
install=${pkgname}.install
source=("ftp://ftp.denx.de/pub/u-boot/u-boot-${pkgver}.tar.bz2"
        '0001-parabola-arm-modifications.patch'
        'extlinux.conf'
        'uEnv.txt')
md5sums=('7d4f65fd43d4d706f5c5650e020d899d'
         'da3d52f785bce02602f88fb85f74de2f'
         '3b3d0e13be08225190c0f733ebf31d9a'
         'd41d8cd98f00b204e9800998ecf8427e')

prepare() {
  cd u-boot-${pkgver}
  patch -Np1 -i ../0001-parabola-arm-modifications.patch
}

build() {
  cd u-boot-${pkgver}

  unset LDFLAGS CFLAGS CXXFLAGS

  make distclean
  make omap3_beagle_config
  make
}

package() {
  cd u-boot-${pkgver}
  mkdir -p "${pkgdir}"/boot/extlinux
  cp MLO u-boot.img "${srcdir}"/uEnv.txt "${pkgdir}"/boot
  cp "${srcdir}"/extlinux.conf "${pkgdir}"/boot/extlinux
}