# $Id$
# Maintainer: Andreas Radke <andyrtr@archlinux.org>
# Maintainer (Parabola): Márcio Silva <coadde@lavabit.com>

pkgbase=claws-mail
pkgname=claws-mail-libre
pkgflag=-libre
pkgver=3.9.0
pkgrel=2
pkgdesc='A GTK+ based e-mail client, without nonfree PalmOS handheld devices support'
arch=(
  i686
  x86_64
  mips64el
)
license=GPL3
url="http://www.$pkgbase.org"
depends=(
  db
  dbus-glib
  desktop-file-utils
  enchant
  gnutls
  gpgme
  gtk2
  hicolor-icon-theme
  'libetpan>=1.1'
  libsm
  startup-notification
)
makedepends=(
  bogofilter
  compface
  spamassassin
)
[ "$CARCH" != "mips64el" ] && makedepends+=(valgrind)
optdepends=(
  'python2:           needed for some tools'
  'perl:              needed for some tools'
  'spamassassin:      adds support for spamfiltering'
  'bogofilter:        adds support for spamfiltering'
)
provides=(
  claws
  $pkgbase=$pkgver
)
conflicts=(
  $pkgbase
)
replaces=(
  $pkgbase
  sylpheed-claws
)
options=(
  '!libtool'
)
install=$pkgbase.install
source=(
  http://downloads.sourceforge.net/sourceforge/sylpheed-claws/$pkgbase-$pkgver.tar.bz2
)
md5sums=(
  4c5ac7b21f0ed17d0f6404124c2229a4
)

build() {
  cd $srcdir/$pkgbase-$pkgver

  sed -i 's@^#!.*python.*@#!/usr/bin/python2@' tools/*.py

  ./configure --prefix=/usr\
    --disable-dillo-viewer-plugin\
    --disable-static\
    --enable-bogofilter-plugin\
    --enable-crash-dialog\
    --enable-enchant\
    --enable-gnutls\
    --enable-jpilot\
    --enable-ldap\
    --enable-pgpmime-plugin\
    --enable-spamassassin-plugin

  make
}

package() {
  cd $srcdir/$pkgbase-$pkgver
  make DESTDIR=$pkgdir install

  # build and install extra tools
  cd tools
  make
   # all executables and .conf files ; only top directory
  find -maxdepth 1 -type f -and -perm /111 -or -name '*.conf' | while read i ; do
    install -D -m755 $i $pkgdir/usr/lib/$pkgbase/tools/$i
  done
}