# $Id$
# Maintainer: BlackIkeEagle <ike DOT devolder AT gmail DOT com>
# Contributor: (sirocco AT ngs.ru)

_pkgbase=doublecmd
pkgbase=doublecmd-libre
pkgname=('doublecmd-gtk2-libre' 'doublecmd-qt-libre')
pkgver=0.5.4
_helpver=0.5.1
pkgrel=2.1
url="http://doublecmd.sourceforge.net/"
arch=('i686' 'x86_64')
license=('GPL')
install="$_pkgbase.install"
makedepends=('lazarus' 'qt4pas' 'gtk2')
optdepends=('lua: scripting' 'p7zip: support for 7zip archives')
source=("http://downloads.sourceforge.net/project/$_pkgbase/Double%20Commander%20Source/$_pkgbase-$pkgver-src.tar.gz"
	"http://downloads.sourceforge.net/project/$_pkgbase/Double%20Commander%20Source/$_pkgbase-help-$_helpver-src.tar.gz"
)
sha256sums=('480b83279adeba007ad5c54f455733fae3d9c9ee61762e6b5a63e2e67b1cd7b7'
            'd9f518e05e089b71aaa31c7d4af8177e77594a02be2c316e85e061e63b4c03e5')

build() {
	cp -a $_pkgbase-$pkgver $_pkgbase-gtk
	cp -a $_pkgbase-$pkgver $_pkgbase-qt

	cd "$srcdir/$_pkgbase-gtk"
	./build.sh beta gtk2

	cd "$srcdir/$_pkgbase-qt"
	./build.sh beta qt
}

package_doublecmd-gtk2-libre() {
	pkgdesc="twin-panel (commander-style) file manager (GTK)"
	depends=('gtk2')
	conflicts=('doublecmd-gtk2')
	replaces=('doublecmd-gtk2')
	provides=("doublecmd-gtk2=${pkgver}" 'doublecmd')
	cd "$srcdir/$_pkgbase-gtk"
	sed -e 's/LIB_SUFFIX=.*/LIB_SUFFIX=/g' -i ./install/linux/install.sh
	./install/linux/install.sh --install-prefix="$pkgdir"

	# install doc
	cd "$srcdir/$_pkgbase-help-$_helpver"
	cp -a * "$pkgdir/usr/share/$_pkgbase/doc/"
}

package_doublecmd-qt-libre() {
	pkgdesc="twin-panel (commander-style) file manager (QT)"
	depends=('qt4pas')
	conflicts=('doublecmd-qt')
	replaces=('doublecmd-qt')
	provides=("doublecmd-qt=${pkgver}" 'doublecmd')
	cd "$srcdir/$_pkgbase-qt"
	sed -e 's/LIB_SUFFIX=.*/LIB_SUFFIX=/g' -i ./install/linux/install.sh
	./install/linux/install.sh --install-prefix="$pkgdir"

	# install doc
	cd "$srcdir/$_pkgbase-help-$_helpver"
	cp -a * "$pkgdir/usr/share/$_pkgbase/doc/"
}