# $Id: PKGBUILD 109557 2014-04-15 23:23:01Z bgyorgy $
# Maintainer: Balló György <ballogyor+arch at gmail dot com>
# Contributor: Stefano Facchini <stefano.facchini@gmail.com>
# Maintainer (Parabola): André Silva <emulatorman@parabola.nu>
# Contributor (Parabola): Daniel Milewski <niitotantei@gmail.com>

_pkgname=gnome-boxes
pkgname=gnome-libre
pkgver=3.12.1
pkgrel=1
pkgdesc="Simple GNOME 3 application to access remote or virtual systems, without nonfree system logos"
arch=('i686' 'x86_64')
url="https://wiki.gnome.org/Apps/Boxes"
license=('LGPL')
provides=$_pkgname=$pkgver
conflicts=$_pkgname
replaces=$_pkgname
depends=('clutter-gtk' 'gtk-vnc' 'libosinfo' 'libsoup' 'libvirt-glib' 'spice-gtk3'
         'libtracker-sparql' 'qemu' 'cdrkit' 'libcdio' 'mtools' 'dconf'
         'gnome-icon-theme' 'gnome-themes-standard')
makedepends=('gobject-introspection' 'intltool' 'itstool' 'spice-protocol' 'vala')
install=$_pkgname.install
source=(http://ftp.gnome.org/pub/GNOME/sources/$_pkgname/${pkgver%.*}/$_pkgname-$pkgver.tar.xz
        libre.patch)
sha256sums=('b5e27756a9c485ce2dea3f8eae867b6c7be70862b16cc44f9b55d86dd633bb83'
            '2a93935ba94b9f327645a92f11d1a3d23cbeab8e5c800e414c6762181f51d4c0')

prepare() {
  cd $_pkgname-$pkgver

  patch -Np1 -i "$srcdir/libre.patch"

  cd help/es
  intltool-update es.po
  msgattrib --no-obsolete -o es.po es.po
}

build() {
  cd $_pkgname-$pkgver
  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --libexecdir=/usr/lib/$_pkgname \
              --disable-static --disable-schemas-compile --enable-smartcard
  make
}

package() {
  cd $_pkgname-$pkgver
  make DESTDIR="$pkgdir" install
}