# $Id: PKGBUILD 107420 2014-03-17 10:06:48Z alucryd $
# Maintainer: Maxime Gauduin <alucryd@gmail.com>
# Contributor: TingPing <tingping@tingping.se>
# Maintainer (Parabola): André Silva <emulatorman@parabola.nu>

_pkgname=hexchat
pkgname=hexchat-libre
pkgver=2.9.6.1
pkgrel=2
pkgdesc='A popular and easy to use graphical IRC (chat) client, without nonfree browser reference (Parabola rebranded)'
arch=('i686' 'x86_64' 'mips64el')
url='http://hexchat.github.io/'
license=('GPL')
depends=('dbus-glib' 'desktop-file-utils' 'hicolor-icon-theme' 'libcanberra' 'libnotify' 'libproxy' 'libsexy' 'pciutils')
makedepends=('perl' 'python')
optdepends=('enchant: Spell check'
            'perl: Perl plugin'
            'python: Python plugin')
install="${_pkgname}.install"
replaces=$_pkgname
conflicts=$_pkgname
provides=$_pkgname=$pkgver
source=("http://dl.hexchat.org/${_pkgname}/${_pkgname}-${pkgver}.tar.xz")
sha256sums=('6267ff3c4d0aec8a808365b384115a769d5001d99dbb10403634667c43966470')

build() {
  cd ${_pkgname}-${pkgver}

# Rebrand to Parabola
  sed -i 's#ArchLinux#Parabola GNU/Linux-libre#' plugins/sysinfo/parse.c

# Remove nonfree browser references
  sed -i '\|NAME Open Link| s|Firefox|Iceweasel|' src/common/hexchat.c
  sed -i '\|NAME Open Link| s|firefox -private %s\\n\\n";|iceweasel -private %s\\n\\n"\\\n		"NAME Open Link in Private Icecat Window\\n"		"CMD !icecat -private %s\\n\\n";|' src/common/hexchat.c

  ./configure --prefix='/usr' --enable-{python='python3.4',shm,spell='libsexy',textfe}
  make
}

package() {
  cd ${_pkgname}-${pkgver}

  make DESTDIR="${pkgdir}" install
}

# vim: ts=2 sw=2 et: