# $Id: PKGBUILD 184270 2013-05-05 10:45:11Z schiv $
# Maintainer: Ray Rashif <schiv@archlinux.org>
# Contributor: tobias <tobias@archlinux.org>
# Contributor: K. Piche <kpiche@rogers.com>
# Contributor: Giovanni Scafora <giovanni@archlinux.org>

_pkgname=hydrogen
pkgname=hydrogen-libre
pkgver=0.9.5.1
pkgrel=4
pkgdesc="An advanced drum machine, without nonfree drumkits recommendation"
arch=('i686' 'x86_64' 'mips64el')
license=('GPL')
url="http://www.hydrogen-music.org/"
depends=('libarchive' 'liblrdf' 'qt4' 'jack')
makedepends=('scons' 'optipng')
replaces=$_pkgname
conflicts=$_pkgname
provides=$_pkgname=$pkgver
source=("http://downloads.sourceforge.net/$_pkgname/$_pkgname-$pkgver.tar.gz"
        'lrdf_raptor2.patch'
        'install.patch')
install=$_pkgname.install
options=('emptydirs')
md5sums=('52f3a528705818c65acf546a3be4c6fb'
         '2124851e890f46158189b5fa90006d40'
         'ce3a83a069b55e46aa532b55e803c9a5')

prepare() {
  cd "$srcdir/$_pkgname-$pkgver"

  # Change to list with only free licensed drumkits
  sed -i -e 's|www.hydrogen-music.org/feeds/drumkit_list.php|repo.parabolagnulinux.org/other/hydrogen-libre/feeds/drumkit_list.php|'\
  {data/{hydrogen.default.conf,doc/manual{.docbook,_nl.html,_es.html,_fr.html,.pot,_fr.po,_es.po,_en.html,_ca.html,_it.html}},gui/src/SoundLibrary/SoundLibraryImportDialog.cpp,libs/hydrogen/src/preferences.cpp} || read

  # fix building with newer raptor
  # see https://bugs.archlinux.org/task/25060
  # TODO: report upstream
  patch -Np1 -i "$srcdir/lrdf_raptor2.patch"

  # fix some install-time issues
  # http://www.assembla.com/spaces/hydrogen/tickets/204
  patch -Np0 -i "$srcdir/install.patch"

  # fix some pngs that break with newer libpng
  # see https://mailman.archlinux.org/pipermail/arch-dev-public/2013-May/024872.html
  msg2 "Fixing PNGs, please wait..."
  find -name '*.png' -exec optipng -quiet -force -fix {} +
}

build() {
  cd "$srcdir/$_pkgname-$pkgver"

  export QTDIR=/usr
  scons prefix=/usr libarchive=1
}

package() {
  cd "$srcdir/$_pkgname-$pkgver"

  scons DESTDIR="$pkgdir" install
}

# vim:set ts=2 sw=2 et: