# $Id$
# Maintainer: Ray Rashif <schiv@archlinux.org>
# Contributor: tobias <tobias@archlinux.org>
# Contributor: K. Piche <kpiche@rogers.com>
# Contributor: Giovanni Scafora <giovanni@archlinux.org>

_pkgname=hydrogen
pkgname=hydrogen-libre
pkgver=0.9.5.1
pkgrel=1
pkgdesc="Advanced Drum Machine (without nonfree licensed drumkits)"
arch=('i686' 'x86_64' 'mips64el')
license=('GPL')
url="http://www.hydrogen-music.org/"
depends=('libarchive' 'liblrdf' 'qt' 'jack')
makedepends=('scons')
#options=('!makeflags')
replaces=("${_pkgname}")
conflicts=("${_pkgname}")
provides=("${_pkgname}=${pkgver}")
source=(http://downloads.sourceforge.net/${_pkgname}/${_pkgname}-${pkgver}.tar.gz
        lrdf_raptor2.patch
        install.patch)
md5sums=('52f3a528705818c65acf546a3be4c6fb'
         '2124851e890f46158189b5fa90006d40'
         'ce3a83a069b55e46aa532b55e803c9a5')

build() {
  cd "${srcdir}/${_pkgname}-${pkgver}"

  # Change to list with only free licensed drumkits
  sed -i "s|www.hydrogen-music.org/feeds/drumkit_list.php|repo.parabolagnulinux.org/other/hydrogen-libre/feeds/drumkit_list.php|" \
  {data/{hydrogen.default.conf,doc/manual{.docbook,_nl.html,_es.html,_fr.html,.pot,_fr.po,_es.po,_en.html,_ca.html,_it.html}},gui/src/SoundLibrary/SoundLibraryImportDialog.cpp,libs/hydrogen/src/preferences.cpp} || read

  export QTDIR=/usr
  patch -Np1 -i "${srcdir}/lrdf_raptor2.patch"
  # http://www.assembla.com/spaces/hydrogen/tickets/204
  patch -Np0 -i "${srcdir}/install.patch"
  scons prefix=/usr libarchive=1
}

package() {
  cd "${srcdir}/${_pkgname}-${pkgver}"

  scons DESTDIR="${pkgdir}" install
}

# vim:set ts=2 sw=2 et: