# $Id: PKGBUILD 271080 2016-07-06 10:08:49Z arojas $
# Maintainer (Arch): Ronald van Haren <ronald@archlinux.org>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>
# Contributor (Arch): Tobias Powalowski <tpowa@archlinux.org>
# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: Márcio Silva <coadde@parabola.nu>

pkgbase=digikam
pkgname=kipi-plugins
_pkgver=5.0.0
pkgver=${_pkgver//-/_}
pkgrel=1.parabola1
pkgdesc="Digital photo management application for KDE"
arch=('i686' 'x86_64' 'armv7h')
license=('GPL')
url="http://www.digikam.org/"
replaces=("${pkgname}-libre")
conflicts=("${pkgname}-libre")
makedepends=('extra-cmake-modules' 'libkipi' 'libksane' 'liblqr' 'opencv' 'boost'
             'opencv' 'doxygen' 'lensfun' 'eigen' 'kdoctools' 'marble' 'kdesignerplugin'
             'kfilemetadata' 'akonadi-contact' 'qt5-multimedia' 'threadweaver' 'kcalcore'
             'knotifyconfig' 'libmediawiki' 'libkvkontakte' 'kqoauth')
source=("http://download.kde.org/stable/${pkgbase}/${pkgbase}-${_pkgver}.tar.xz"
        "libre.patch")
sha1sums=('e0dec2eba9ab3a51d632b69b3dd6daf8dca64a45'
          'ed2a01c4a837b50d3c1ad0d4758f2fa3bb44402f')

prepare() {
  mkdir -p build

# Build fails
  sed -e '/add_subdirectory(showfoto)/d' -i ${pkgbase}-${_pkgver}/doc-translated/digikam/CMakeLists.txt

  cd ${pkgbase}-${_pkgver}
  patch -p1 -i ../libre.patch
}

build() {
  cd build

  cmake ../${pkgbase}-${_pkgver} \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_INSTALL_LIBDIR=lib \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_SKIP_RPATH=ON \
    -DBUILD_TESTING=OFF \
    -DENABLE_KFILEMETADATASUPPORT=ON \
    -DENABLE_MEDIAPLAYER=ON \
    -DENABLE_AKONADICONTACTSUPPORT=ON \
    -DENABLE_MYSQLSUPPORT=ON \
    -DENABLE_OPENCV3=ON
  make
}

package_kipi-plugins() {
  pkgdesc="A collection of plugins extending the KDE graphics and image applications as digiKam, without nonfree suggestions"
  depends=('kio' 'libkipi')
  optdepends=('libmediawiki: MediaWiki Export plugin'
              'libkvkontakte: VKontakte.ru Exporter plugin'
              'kqoauth: OAuth authentication for imgur')

  cd build/extra
  make DESTDIR="$pkgdir" install
  cd $srcdir/build/doc/kipi-plugins
  make DESTDIR="$pkgdir" install
  cd $srcdir/build/doc-translated/kipi-plugins
  make DESTDIR="pkgdir" install
  cd $srcdir/build/po
  make DESTDIR="$pkgdir" install

# Provided by digikam
  rm "$pkgdir"/usr/share/locale/*/LC_MESSAGES/digikam.mo
}