# $Id$
# Maintainer: Lukas Jirkovsky <l.jirkovsky@gmail.com>
# Initial contributor: flixie <69one@gmx.net>
# Contributor: Imanol Celaya <ornitorrincos@archlinux-es.org>
# Maintainer (Parabola): Márcio Silva <coadde@lavabit.com>
pkgname=luxrender-libre
pkgver=1.0rc2
_pkgver=008805644181
pkgrel=2
pkgdesc="Rendering system for physically correct, unbiased image synthesis (without OpenCL)"
arch=('i686' 'x86_64' 'mips64el')
url="http://www.luxrender.net/"
license=('GPL')
depends=('boost-libs' 'freeimage' 'openexr')
optdepends=('luxblend25: Blender exporter' 'qt: Qt GUI' \
            'python: Python interface (pylux)')
makedepends=('cmake' 'boost' 'qt' 'luxrays-libre' 'python')
replaces=('luxrender')
conflicts=('luxrender')
provides=("luxrender=$pkgver")
source=(https://bitbucket.org/luxrender/lux/get/$_pkgver.tar.bz2 \
        boost_1.50_fix.diff)
md5sums=('1922ccce6f70e7d707b340e2415875cd'
         '8c7774bb0c97aadd77d9e665d8fa4aab')

build() {
  cd "$srcdir"/luxrender-lux-$_pkgver

  # fix for boost 1.50
  # the boost::TIME_UTC has been renamed due to the conflict with C++11
  patch -Np1 < "$srcdir"/boost_1.50_fix.diff || true

  export CXXFLAGS="$CXXFLAGS -lpthread"
  cmake -DCMAKE_INSTALL_PREFIX=/usr \
    -DLUXRAYS_DISABLE_OPENCL=ON \
    -DPYTHON_CUSTOM=ON \
    -DPYTHON_LIBRARIES=/usr/lib/libpython3.2mu.so \
    -DPYTHON_INCLUDE_PATH=/usr/include/python3.2mu/ \
    .
  make
}

package() {
  cd "$srcdir"/luxrender-lux-$_pkgver
  make DESTDIR="$pkgdir" install

  # fix library path on x86_64
  [ "$CARCH" = "x86_64" ] && mv "$pkgdir"/usr/lib64 "$pkgdir"/usr/lib

  #install pylux
  install -D -m644 pylux.so "$pkgdir"/usr/lib/python3.2/pylux.so
}

# vim:set ts=2 sw=2 et: