# Maintainer (Arch): Martin Wimpress <code@flexion.org>
# Maintainer: André Silva <emulatorman@parabola.nu>

_ver=1.9
pkgname=mate-icon-theme-faenza
pkgver=${_ver}.90
pkgrel=1.parabola1
pkgdesc="Faenza icon theme for MATE, without nonfree distros and application icons"
url="http://mate-desktop.org"
arch=('any')
license=('LGPL')
depends=('gtk-update-icon-cache')
makedepends=('git' 'icon-naming-utils' 'mate-common')
replaces=(${pkgname}-libre)
conflicts=(${pkgname}-libre)
options=(!strip)
groups=('mate-extra' 'mate-extra-gtk3')
source=("${pkgname}"::"git+https://github.com/mate-desktop/${pkgname}.git#commit=adbbe4c89eee60372d1ef3e25e374f18585d0fbd")
sha1sums=('SKIP')
install=${pkgname}.install

#pkgver() {
#    cd "${srcdir}/${pkgname}"
#    printf "%s.%s.%s" "${_ver}.90"
#}

prepare() {
    cd "${srcdir}/${pkgname}"
    NOCONFIGURE=1 ./autogen.sh
    # remove nonfree distros and application logos
    for nonfree in debian fedora mandriva redhat suse ubuntu alien-arena flash rpmdrake teamviewer novell skype playonlinux picasa spotify; do
     find -name *$nonfree* -delete
    done
}

build() {
    cd "${srcdir}/${pkgname}"
    ./configure \
        --prefix=/usr
    make
}

package() {
    cd "${srcdir}/${pkgname}"
    make DESTDIR="${pkgdir}" install
    rm -f "${pkgdir}/usr/share/icons/matefaenza/icon-theme.cache"
}