# Maintainer: Márcio Silva <coadde@parabola.nu>
# Contributor: André Silva <emulatorman@parabola.nu>

pkgbase=mesa
_pkgname=libcl
pkgname=$pkgbase-$_pkgname
pkgver=10.4.5
pkgrel=1
pkgdesc='Mesa 3-D OpenCL library and ICD loader'
arch=('i686' 'x86_64' 'mips64el')
url="http://${pkgbase}3d.sourceforge.net"
license=('custom')
depends=("$pkgbase" 'libclc' 'clang')


makedepends=('dri2proto' 'dri3proto' 'glproto' 'presentproto' 'python2')
provides=("$_pkgname")
conflicts=("$_pkgname" "$_pkgname-libre" 'opencl-nvidia' 'opencl-nvidia-304xx')
replaces=("$_pkgname" "$_pkgname-libre" 'opencl-nvidia' 'opencl-nvidia-304xx')
source=(ftp://ftp.freedesktop.org/pub/$pkgbase/$pkgver/${pkgbase^}Lib-$pkgver.tar.bz2{,.sig})
sha512sums=('13e3b0df0bd154eacb369ee0b39e60837a2694f0b0c5cd9a43a983ad5b31825f7b0743961546e15ddc501cefdb2c2a2a0d855d5971921fecc58faa630154f6df'
            'SKIP')
validpgpkeys=('8703B6700E7EE06D7A39B8D6EDAE37B02CEB490D') # Emil Velikov <emil.l.velikov@gmail.com>

build() {
  cd $srcdir/${pkgbase^}-$pkgver

  autoreconf -vfi # our automake is far too new for their build system :)

  ./configure --prefix=/usr \
    --sysconfdir=/etc \
    --with-gallium-drivers=r300,r600,radeonsi,nouveau,svga,swrast \
    --with-egl-platforms=x11,drm,wayland \
    --enable-llvm-shared-libs \
    --enable-egl \
    --enable-gallium-llvm \
    --enable-opencl \
    --with-clang-libdir=/usr/lib
  # --with-gallium-drivers, --with-egl-platforms, --enable-egl, --disable-gallium-egl, --disable-gallium-gbm, --enable-gallium-llvm
  # added, due are not r300, nouveau, svga and swrast gallium-pipe files on opencl-mesa package
  make

  # fake installation
  mkdir $srcdir/fakeinstall
  make DESTDIR=$srcdir/fakeinstall install
}

package() {
  cd $srcdir/${pkgbase^}-$pkgver

  install -vm755 -d $pkgdir/usr/lib/
  mv -v $srcdir/fakeinstall/usr/lib/libOpenCL* $pkgdir/usr/lib/

  install -vm755 -d $pkgdir/usr/lib/gallium-pipe
  mv -v $srcdir/fakeinstall/usr/lib/gallium-pipe/pipe_{nouveau,r300,swrast,vmwgfx}.so $pkgdir/usr/lib/gallium-pipe/

  install -vm755 -d $pkgdir/usr/share/licenses/$pkgname
  install -vm644 docs/COPYING      $pkgdir/usr/share/licenses/$pkgname
  install -vm644 docs/license.html $pkgdir/usr/share/licenses/$pkgname/LICENSE
}

# vim:set ts=2 sw=2 et: