# Maintainer: Luke Shumaker <lukeshu@sbcglobal.net>

pkgname=(parabolaweb-utils parabolaweb-dev)
pkgver=20140624.2
pkgdesc="Utilities for managing the ParabolaWeb website application"
url="https://projects.parabolagnulinux.org/packages/parabolaweb-utils.git/"
license=('GPL2')

# The commit to get dependency info for
# Bump pkgrel instead of pkgver if updating this is the only change
_parabolaweb_commit=724f8c309c97aa9af7f963687342e8f37e682204

pkgrel=1
epoch=1
arch=('i686' 'x86_64')

source=(
	"https://projects.parabolagnulinux.org/packages/$pkgname.git/snapshot/$pkgname-$pkgver.tar.bz2"
	"requirements_prod-${_parabolaweb_commit}.txt::https://projects.parabolagnulinux.org/parabolaweb.git/plain/requirements_prod.txt?id=${_parabolaweb_commit}"
)
md5sums=('cf4c887e49b046bf937153681f148f25'
         '8bf17af4e66f552864bfdc0fd1d472f1')

build() {
	cd "$srcdir/$pkgname-$pkgver"
	prod_file="file://${srcdir}/requirements_prod-${_parabolaweb_commit}.txt" make
}

package_parabolaweb-utils() {
	cd "$srcdir/$pkgbase-$pkgver"
	depends=($(< depends.txt))
	backup=('etc/conf.d/parabolaweb')
	make install DESTDIR="$pkgdir"
}

package_parabolaweb-dev() {
	cd "$srcdir/$pkgbase-$pkgver"
	pkgdesc="Depends on packages needed to develop ParabolaWeb"
	depends=($(sed -r -e 's/\s*#.*//' depends_make.txt))
}