# Maintainer (Arch): Daniel Micay <danielmicay@gmail.com>
# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: Gaming4JC <gaming4jc2@yahoo.com>

_pkgname=paxd
pkgname=paxd-libre
pkgver=1.2
pkgrel=1
pkgdesc='PaX exception daemon (a libre fork of paxd)'
arch=(i686 x86_64)
url='https://github.com/g4jc/paxd-libre/'
license=(MIT)
replaces=($_pkgname linux-pax-flags)
conflicts=($_pkgname linux-pax-flags)
provides=($_pkgname linux-pax-flags)
depends=(glibc)
source=(https://github.com/g4jc/paxd-libre/archive/$pkgver.tar.gz 10-enable-pax.conf)
md5sums=('20793d7b60d3d8894a4933b8bca5612d'
         'a40677d2cd39ada4c2560927c67e0ea2')
backup=(etc/paxd-libre.conf)

build() {
  cd $pkgname-$pkgver
  make CC=gcc
}

package() {
  cd $pkgname-$pkgver
  mkdir -p "$pkgdir/usr/lib/systemd/system/sysinit.target.wants"
  make PREFIX=/usr DESTDIR="$pkgdir" install
  install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  install -Dm644 ../10-enable-pax.conf "$pkgdir/usr/lib/sysctl.d/10-enable-pax.conf"
}