# Maintainer: Márcio Silva <coadde@parabola.nu>
# based of perl

_pkgname=perl
pkgname=perl-static
pkgver=5.22.1
pkgrel=2.1
pkgdesc="A highly capable, feature-rich programming language (static libraries only)"
arch=(i686 x86_64 armv7h)
license=('GPL' 'PerlArtistic')
url="http://www.perl.org"
depends=('gdbm-static' 'db-static' 'perl')
source=(http://www.cpan.org/src/5.0/perl-${pkgver}.tar.bz2
        CVE-2016-2381_duplicate_env.diff)
options=('makeflags' '!purge' 'emptydirs' 'staticlibs')
md5sums=('67242b9bd642b458bec884ed2a040910'
         'a108f258b9ba1504b6051d123ccaa623')

prepare() {
  cd ${srcdir}/${_pkgname}-${pkgver}

  patch -p1 -i "$srcdir/CVE-2016-2381_duplicate_env.diff"
}

build() {
  cd ${srcdir}/${_pkgname}-${pkgver}

  if [ "${CARCH}" = "x86_64" ]; then
    # for x86_64
    arch_opts="-Dcccdlflags='-fPIC'"
  else
    # for i686
    arch_opts=""
  fi

  ./Configure -des -Dusethreads -Duseshrplib=false -Doptimize="${CFLAGS}" \
    -Dprefix=/usr \
    -Darchlib=/usr/lib/perl5/core_perl \
    -Dinc_version_list=none \
    ${arch_opts} \
    -Dlddlflags="-static -nostartfiles ${LDFLAGS}" -Dldflags="${LDFLAGS}" \
    -Ddynamic_ext=none -Dso=none
  make
}

check() {
  cd ${srcdir}/${_pkgname}-${pkgver}
#  TEST_JOBS=$(echo $MAKEFLAGS | sed 's/.*-j\([0-9][0-9]*\).*/\1/') make test_harness
##  make test
}

package() {
  cd ${srcdir}/${_pkgname}-${pkgver}
  make DESTDIR="$pkgdir" install

  # remove conflicting files
  rm -vr ${pkgdir}/usr/{bin,lib/perl5/{5,s}*,share}
  rm -vr ${pkgdir}/usr/lib/perl5/core_perl/{B,Compress,Data,Devel,Digest,Encode,File,Filter,Hash,I18N,IO,IPC,List,Math,MIME,PerlIO,Scalar,Sub,Sys,Tie,Time,Unicode,threads}
  rm -v ${pkgdir}/usr/lib/perl5/core_perl/{.packlist,*.{pl,pm,pod},CORE/*.h}
}