# $Id: PKGBUILD 96569 2013-09-01 16:36:10Z speps $
# Maintainer: speps <speps at aur dot archlinux dot org>
# Maintainer (Parabola): André Silva <emulatorman@parabola.nu>

_name=QupZilla
_pkgname=qupzilla
pkgname=qupzilla-libre
pkgver=1.4.4
pkgrel=1
pkgdesc="Cross-platform QtWebKit browser, with DuckDuckGo HTML support"
arch=(i686 x86_64 mips64el)
url="http://www.qupzilla.com/"
license=('GPL3')
depends=('qtwebkit' 'hunspell')
optdepends=('bash-completion: bash completion support')
install="$_pkgname.install"
replaces=$_pkgname
conflicts=$_pkgname
provides=$_pkgname=$pkgver
source=("$_pkgname-$pkgver.tar.gz::https://github.com/$_name/$_pkgname/tarball/v$pkgver"
         'searchenginesmanager.cpp.sed'
         'speeddial.cpp.sed'
         'start.html.sed')
md5sums=('cfbf5cd23d184275c389c79a39a28631'
         '1d926e97a5b287d40fb695f6516f2a06'
         '0f166fa102af975b3b8ac030d477e9b8'
         '77120a0c39ba8254e5b2c273910f029a')

prepare() {
  cd "$srcdir/$_name-$_pkgname-"*

  # remove Google and Youtube support, replaces it to DDG HTML
  sed -i -f $srcdir/searchenginesmanager.cpp.sed src/lib/opensearch/searchenginesmanager.cpp
  sed -i -f $srcdir/speeddial.cpp.sed src/lib/plugins/speeddial.cpp
  sed -i -f $srcdir/start.html.sed src/lib/data/html/start.html
}

build() {
  cd "$srcdir/$_name-$_pkgname-"*

  # enable webgl support
  export USE_WEBGL=true

  qmake-qt4 QUPZILLA_PREFIX=/usr/
  make
}

package() {
  cd "$srcdir/$_name-$_pkgname-"*
  make INSTALL_ROOT="$pkgdir/" install

  # zsh completion
  install -Dm644 linux/completion/zsh_completion.sh \
    "$pkgdir/usr/share/zsh/site-functions/_$_pkgname"
}

# vim:set ts=2 sw=2 et: