# $Id: PKGBUILD 90358 2013-05-11 23:22:13Z speps $
# Maintainer: speps <speps at aur dot archlinux dot org>
# Maintainer (Parabola): André Silva <emulatorman@parabola.nu>

_name=QupZilla
_pkgname=qupzilla
pkgname=qupzilla-libre
pkgver=1.4.3
pkgrel=1.2
pkgdesc="Cross-platform QtWebKit browser, with DuckDuckGo HTML support"
arch=(i686 x86_64 mips64el)
url="http://www.qupzilla.com/"
license=('GPL3')
depends=('qtwebkit' 'hunspell')
optdepends=('bash-completion: bash completion support')
install="$_pkgname.install"
replaces=$_pkgname
conflicts=$_pkgname
provides=$_pkgname=$pkgver
source=("$_pkgname-$pkgver.tar.gz::https://github.com/$_name/$_pkgname/tarball/v$pkgver"
        'libre.patch')
md5sums=('20187fcce11dbba876e1ee7dc5e32583'
         '20c8304eb790cda5491078bf5bf71d49')

prepare() {
  cd "$srcdir/$_name-$_pkgname-"*

  # remove Google, Youtube and Facebook support, replaces it to DDG HTML
  patch -Np1 -i $srcdir/libre.patch
}

build() {
  cd "$srcdir/$_name-$_pkgname-"*

  # enable webgl support
  export USE_WEBGL=true

  qmake-qt4 QUPZILLA_PREFIX=/usr/
  make
}

package() {
  cd "$srcdir/$_name-$_pkgname-"*
  make INSTALL_ROOT="$pkgdir/" install

  # zsh completion
  install -Dm644 linux/completion/zsh_completion.sh \
    "$pkgdir/usr/share/zsh/site-functions/_$_pkgname"
}

# vim:set ts=2 sw=2 et: