# Maintainer: Rémy Oudompheng <remy.archlinux.org>
# Maintainer (Parabola): Michał Masłowski <mtjm@mtjm.eu>
# Contributor (Parabola): André Silva <emulatorman@parabola.nu>

pkgname=texlive-fontsextra-libre
_pkgname=texlive-fontsextra
pkgver=2013.31570
_revnr=${pkgver#2013.}
pkgrel=1
pkgdesc="TeX Live - all sorts of extra fonts, without nonfree add-on packages"
license=('GPL')
arch=(any)
depends=('texlive-core')
groups=('texlive-most')
replaces=('texlive-fontsextra')
conflicts=('texlive-fontsextra')
provides=('texlive-fontsextra')
url='http://tug.org/texlive/'
mksource=("ftp://ftp.archlinux.org/other/texlive/$_pkgname-$pkgver-src.zip")
noextract=("$_pkgname-$pkgver-src.zip")
source=("https://repo.parabolagnulinux.org/other/$pkgname/$pkgname-$pkgver-src.tar.xz" "$_pkgname.maps")
options=('!emptydirs')
options=(!strip)
install=texlive.install
mkmd5sums=('3f519371dd2e22e5b32daa461b89aea2')
md5sums=('e6b12e482913169f44c54172316416bc'
         'f489cc5f762dcdbe6acb11624de7e138')

mksource() {
   mkdir $_pkgname-$pkgver
   pushd $_pkgname-$pkgver
   bsdtar xfv ../$_pkgname-$pkgver-src.zip

   # remove nonfree packages
   # No specific free license.
   rm -v ogham.tar.xz
   # Remove them from package list.
   sed -ri '/^ogham /d' CONTENTS

   popd
}

build() {
   cd $srcdir/$_pkgname-$pkgver
   for p in *.tar.xz; do
	   bsdtar -xf $p
   done
   rm -rf {tlpkg,doc,source} || true
}

package() {
   cd $srcdir/$_pkgname-$pkgver
   install -m755 -d $pkgdir/var/lib/texmf/arch/installedpkgs
   sed -i '/^#/d' CONTENTS
   install -m644 CONTENTS $pkgdir/var/lib/texmf/arch/installedpkgs/${_pkgname}_${_revnr}.pkgs
   install -m644 $srcdir/$_pkgname.maps $pkgdir/var/lib/texmf/arch/installedpkgs/
   install -m755 -d $pkgdir/usr/share
   wanteddirs=$(for d in *; do test -d $d && [[ $d != texmf* ]] && echo $d; done) || true
   for dir in $wanteddirs; do
     find $dir -type d -exec install -d -m755 $pkgdir/usr/share/texmf-dist/'{}' \;
     find $dir -type f -exec install -m644 '{}' $pkgdir/usr/share/texmf-dist/'{}' \;
   done
   if [[ -d texmf-dist ]]; then
     find texmf-dist -type d -exec install -d -m755 $pkgdir/usr/share/'{}' \;
     find texmf-dist -type f -exec install -m644 '{}' $pkgdir/usr/share/'{}' \;
   fi
   if [[ -d $pkgdir/usr/share/texmf-dist/scripts ]]; then
     find $pkgdir/usr/share/texmf-dist/scripts -type f -exec chmod a+x '{}' \;
   fi
}