# $Id: PKGBUILD 237178 2015-04-15 16:59:36Z arojas $
# Maintainer (Arch): Ronald van Haren <ronald@archlinux.org>
# Contributor (Arch): Andrea Scarpino <andrea@archlinux.org>
# Contributor (Arch): damir <damir@archlinux.org>
# Maintainer: André Silva <emulatorman@parabola.nu>

pkgname=amarok
pkgver=2.8.0
pkgrel=6.nonprism1
pkgdesc="The powerful music player for KDE, without Amazon MP3 store support"
arch=("i686" "x86_64")
url="http://amarok.kde.org/"
license=('GPL2' 'LGPL2.1' 'FDL')
replaces=(${pkgname}-nonprism)
conflicts=(${pkgname}-nonprism)
depends=('kdebase-runtime' 'mariadb' 'qtscriptgenerator' 'taglib-extras'
        'liblastfm' 'ffmpeg' 'libofa' 'qjson')
makedepends=('pkgconfig' 'automoc4' 'cmake' 'libgpod' 'libmtp' 'loudmouth'
             'libmygpo-qt' 'mesa')
optdepends=("libgpod: support for Apple iPod audio devices"
	        "libmtp: support for portable media devices"
        	"loudmouth: backend needed by mp3tunes for syncing"
            "ifuse: support for Apple iPod Touch and iPhone"
            "libmygpo-qt: gpodder.net Internet Service")
install="${pkgname}.install"
source=("http://download.kde.org/stable/${pkgname}/${pkgver}/src/${pkgname}-${pkgver}.tar.bz2"
        'remove-amazon-references-on-docs.patch')
sha1sums=('e76ccd53c05d57f9457d74cd08c2c41383c00937'
          'eed2616fd1465cd16f86f2e3554e3b34b83557af')

prepare() {
  cd ${srcdir}/${pkgname}-${pkgver}
  sed -i '\|amzdownloader|d' utilities/CMakeLists.txt
  sed -i '\|amazon|d' src/services/CMakeLists.txt
  patch -Np1 -i ${srcdir}/remove-amazon-references-on-docs.patch
  cd ..
  mkdir build
}

build() {
  cd build
  cmake ../${pkgname}-${pkgver} \
    -DCMAKE_BUILD_TYPE=Release \
    -DKDE4_BUILD_TESTS=OFF \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DWITH_NepomukCore=OFF \
    -DWITH_Soprano=OFF
  make
}

package(){
  cd build
  make DESTDIR="${pkgdir}" install
}