# $Id: PKGBUILD 211817 2014-04-27 16:25:16Z andyrtr $
# Maintainer (Arch): Andreas Radke <andyrtr@archlinux.org>
# Maintainer: Márcio Silva <coadde@parabola.nu>

_pkgname=claws-mail
pkgname=$_pkgname-nonprism
pkgver=3.9.3
pkgrel=4
pkgdesc="A GTK+ based e-mail client, without libgdata support"
arch=('i686' 'x86_64' 'mips64el')
license=('GPL3')
url="http://www.$_pkgname.org"
depends=('gtk2' 'gnutls' 'startup-notification' 'enchant' 'gpgme' 'libetpan' 'compface'
         'libsm' 'dbus-glib' 'hicolor-icon-theme' 'desktop-file-utils')
makedepends=('spamassassin' 'bogofilter' 'valgrind' 
             # dependencies for plugins
             'libsoup' 'webkitgtk2' 'libnotify' 'libcanberra' 'poppler-glib' 'pygtk') 
             #'libchamplain' needed for geolocation plugin, disabled for now - most time it's not compatible with current gnome releases
optdepends=('python2:           needed for some tools and python plugin'
            'perl:              needed for some tools and perl plugin'
            'spamassassin:      adds support for spamfiltering'
            'bogofilter:        adds support for spamfiltering'
            'libnotify:         for notification plugin'
            'libcanberra:       for notification plugin'
            'dbus:              for notification plugin'
            'libxml2:           for gtkhtml2_viewer and rssyl plugins'
            'curl:              for gtkhtml2_viewer, vcalendar, rssyl and spamreport plugins'
            'libarchive:        for archive plugin and various other plugins'
            'libytnef:          for tnef_parse plugin'
            'webkitgtk2:        for the fancy webkit html plugin'
            'libsoup:           for the fancy webkit html plugin'
	        'poppler-glib:      for pdf viewer plugin'
	        'ghostscript:       for pdf viewer plugin')
replaces=("$_pkgname" "sylpheed-claws" "$_pkgname-extra-plugins" "$_pkgname-libre" "$_pkgname-libre-nonprism")
conflicts=("$_pkgname" "$_pkgname-extra-plugins")
provides=("$_pkgname=$pkgver" 'claws')
install=$_pkgname.install
source=(http://downloads.sourceforge.net/sourceforge/sylpheed-claws/$_pkgname-$pkgver.tar.bz2{,.asc}
        claws-ssl-1.patch
        claws-ssl-2.patch
        claws-ssl-3.patch)
md5sums=('0158b5e6b6d6866f9a75fd288a4edf04'
         'SKIP'
         '02e5fc5dba976208dfabf23d7666681d'
         'dd53ff284cf802ef639bf92fac996d12'
         'e8c2ce77c8df7a2c514a4547337304d8')

prepare() {
  cd $_pkgname-$pkgver
  # fix ssl certificate verification with libetpan >= 1.4
  patch -Np1 < $srcdir/claws-ssl-1.patch
  patch -Np1 < $srcdir/claws-ssl-2.patch
  patch -Np1 < $srcdir/claws-ssl-3.patch
  autoreconf -vfi
}

build() {
  cd $_pkgname-$pkgver

  # fixes for python2
  export PYTHON="/usr/bin/python2"
  sed -i 's@^#!.*python.*@#!/usr/bin/python2@' tools/*.py
  sed -i 's:python -c:python2 -c:g' configure

  setarch $CARCH ./configure --prefix=/usr --disable-static \
    --enable-enchant \
    --enable-gnutls \
    --enable-ldap \
    --enable-crash-dialog \
    --enable-pgpmime-plugin \
    --enable-spamassassin-plugin \
    --enable-bogofilter-plugin \
    --disable-gdata-plugin
    #--help
  setarch $CARCH make
}

package() {
  cd $_pkgname-$pkgver
  setarch $CARCH make DESTDIR=$pkgdir install

  # build and install extra tools
  cd tools
  setarch $CARCH make
   # all executables and .conf files ; only top directory
  find -maxdepth 1 -type f -and -perm /111 -or -name '*.conf' | while read i ; do
      install -D -m755 $i \
        $pkgdir/usr/lib/$_pkgname/tools/$i
  done
}