# $Id: PKGBUILD 124423 2014-12-23 22:18:31Z spupykin $
# Maintainer (Arch): Sergej Pupykin <pupykin.s+arch@gmail.com>
# Maintainer (Arch):  Christian Himpel <chressie at gmail dot com>
# Contributor (Arch): Johannes Hanika <hanatos at gmail dot com>

pkgname=darktable
pkgver=1.6.1
pkgrel=1.nonprism1
pkgdesc="Utility to organize and develop raw images, without flickcurl support"
arch=('i686' 'x86_64' 'mips64el')
url=http://darktable.sf.net/
license=('GPL3')
replaces=(${pkgname}-nonprism)
conflicts=(${pkgname}-nonprism)
depends=('exiv2>=0.18' 'intltool>=0.40' 'lcms2' 'lensfun>=0.2.3' 'libglade' 'dbus-glib'
	 'curl' 'libsecret' 'libgphoto2' 'openexr' 'sqlite' 'libxslt'
	 'libsoup' 'gtk-engines' 'json-glib')
makedepends=('intltool>=0.40' 'cmake' 'librsvg')
optdepends=('librsvg')
install=darktable.install
source=(https://github.com/darktable-org/darktable/archive/release-$pkgver.tar.gz)
md5sums=('86c2d90302ab1e57136d2728437db718')

prepare() {
  cd "$srcdir/$pkgname-release-$pkgver/cmake"
  mv version.cmake.cmake version.cmake
}

build() {
  cd "$srcdir/$pkgname-release-$pkgver"
  mkdir -p build
  cd build
  CXXFLAGS+=" -fpermissive"
  cmake \
      -DCMAKE_INSTALL_PREFIX=/usr \
      -DCMAKE_BUILD_TYPE=Release \
      -DDONT_INSTALL_GCONF_SCHEMAS=True \
      -DBINARY_PACKAGE_BUILD=1 \
      -DUSE_GCONF_BACKEND=Off \
      -DBUILD_USERMANUAL=False \
      -DUSE_LIBSECRET=On \
      -DUSE_GNOME_KEYRING=Off \
      -DUSE_USE_FLICKR=Off \
      ..
  make
}

package() {
  cd "$srcdir/$pkgname-release-$pkgver/build"
  make DESTDIR="$pkgdir" install
  mv "${pkgdir}/usr/share/doc/darktable" "${pkgdir}/usr/share/doc/${pkgname}-${pkgver}"
}