# $Id: PKGBUILD 246427 2015-09-17 13:48:00Z heftig $
# Maintainer (Arch): Ionut Biru <ibiru@archlinux.org>
# Maintainer: Márcio Silva <coadde@parabola.nu>

pkgname=gnome-online-accounts
pkgver=3.16.4.1
pkgrel=1.nonprism1
pkgdesc="GNOME service to access online accounts, without support for unsafe and dangerous for privacy protocols"
arch=(i686 x86_64)
url="http://www.gnome.org"
license=('GPL')
conflicts=("${pkgname}-coherence" "${pkgname}-nonprism" )
replaces=("${pkgname}-coherence" "${pkgname}-nonprism")
depends=('webkit2gtk' 'json-glib' 'libnotify' 'rest' 'libsecret' 'telepathy-glib' 'krb5' 'gcr')
makedepends=('intltool' 'libxslt' 'gobject-introspection' 'docbook-xsl')
install=$pkgname.install
source=(http://ftp.gnome.org/pub/gnome/sources/$pkgname/${pkgver:0:4}/$pkgname-$pkgver.tar.xz)
sha256sums=('68c688730a4a0be0a29e77106a78681fd0ea2c4e1aabafe4df7e20a22dbdb120')

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr --libexecdir=/usr/lib/$pkgname --disable-static \
    --disable-exchange --disable-facebook -disable-flickr \
    --disable-google --enable-imap-smtp --disable-kerberos \
    --enable-owncloud --disable-pocket --enable-telepathy \
    --disable-windows-live --disable-twitter --disable-yahoo \
    --enable-media-server --disable-foursquare
  make
}

package() {
  cd $pkgname-$pkgver
  make -j1 DESTDIR="$pkgdir" install
}

# vim:set ts=2 sw=2 et: