# Contributor (Arch)     : Vincent Bernardoff <vb@luminar.eu.org>
# Maintainer  (Parabola) : Aurélien DESBRIÈRES <aurelien@hackers.camp>

pkgname=aspcud
groups=('potassco')
pkgver=1.9.0
pkgrel=1.1
pkgdesc="Solver for package dependencies"
arch=('x86_64' 'i686')
url="http://potassco.sourceforge.net/"
license=('GPL3')
depends=('clasp>=2.1.3' 'gringo>=4.2.1')
conflicts=('aspcud-svn')
makedepends=('boost' 'cmake' 're2c')
source=(
    "http://downloads.sourceforge.net/project/potassco/${pkgname}/${pkgver}/${pkgname}-${pkgver}-source.tar.gz"
    "boost.patch"
)
md5sums=(
    '9d014548e36480957cb97486e6312bea'
    '6c2dda3cf7dd76bc41d1c8ed379dc5ed'
)

build() {
    cd "$srcdir/$pkgname-$pkgver-source"
    patch -p0 < "$srcdir/boost.patch"
    mkdir -p build/release
    cd build/release
    cmake \
	-DCMAKE_INSTALL_PREFIX:PATH=/usr \
	-DCUDF2LP_LOC=cudf2lp \
    	-DGRINGO_LOC=gringo \
	-DCLASP_LOC=clasp \
	-DCMAKE_BUILD_TYPE=Release ../..
    make
}

package() {
    cd "$srcdir/$pkgname-$pkgver-source"
    cd build/release
    make DESTDIR=${pkgdir} install
}