# Maintainer (Arch): Alad Wenter <alad@archlinux.info>
# Contributor (Arch): Xavier D. <magicrhesus@ouranos.be>
# Contributor (Arch): Valere Monseur <valere.monseur@ymail.com>
pkgname=eid-mw
pkgver=4.0.6_1620
_pkgver=tcm227_258906
pkgrel=3
pkgdesc="The eID middleware for the Belgian eID"
url="http://eid.belgium.be/"
arch=('i686' 'x86_64')
license=('LGPL3')
depends=('pcsclite' 'gtk2')
optdepends=('firefox: extension for Belgian eid'
	'acsccid: ACS CCID smart card readers'
	'ccid: A generic USB Chip/Smart Card Interface Devices driver'
	'pcsc-tools: PC/SC smartcard tools')
source=("http://eid.belgium.be/nl/binaries/${pkgname}-${pkgver//_/-}.tar_${_pkgver//_/-}.gz")
sha256sums=('1ecb30f9f318bdb61a8d774fe76b948eb5841d4de6fee106029ed78daa7efbf2')
options=('!libtool')
     
build() {
	cd "${srcdir}/${pkgname}-${pkgver%_*}"
	./configure --prefix=/usr --libexecdir=/usr/bin
	make
}

package() {
	cd "${srcdir}/${pkgname}-${pkgver%_*}"
	make install DESTDIR="${pkgdir}"
}
     
# vim:set ts=2 sw=2 et: