# Maintainer (Arch): Denis Yantarev <denis dot yantarev at gmail dot com>
# Contributor (Arch): SJ_UnderWater
# Contributor (Arch): Dominik Dingel <mail at wodar dot de>
# Contributor (Arch): William Udovich <nerdzrule7 at earthlink dot net>
# Contributor (Arch): Farhan Yousaf <farhany at xaviya dot com>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>

pkgname=netatalk
pkgver=3.1.8
pkgrel=1
pkgdesc='Open-source implementation of the Apple Filing Protocol'
arch=('i686' 'x86_64' 'armv6h' 'armv7h')
url='http://netatalk.sourceforge.net'
license=('GPL')
depends=('avahi>=0.6' 'libldap' 'libgcrypt>=1.2.3' 'libevent' 'python2' 'dbus-glib' 'python2-dbus')
replaces=('netatalk-git' 'netatalk2')
backup=('etc/afp.conf'
	'etc/extmap.conf')
install=$pkgname.install
source=(http://downloads.sourceforge.net/project/$pkgname/$pkgname/$pkgver/$pkgname-$pkgver.tar.bz2
	python2.patch)

prepare() {
	cd "$srcdir/$pkgname-$pkgver"
	patch -p0 < "$srcdir/python2.patch"
}

build() {
	cd "$srcdir/$pkgname-$pkgver"
	autoreconf -fi
	CFLAGS="-Wno-unused-result -O2" \
		./configure --prefix=/usr --localstatedir=/var/state --sysconfdir=/etc \
		--sbindir=/usr/bin --enable-silent-rules --with-init-style=systemd \
		--with-cracklib --with-cnid-cdb-backend --enable-pgp-uam --with-libevent=no
	make
}

package() {
	cd "$srcdir/$pkgname-$pkgver"
	make DESTDIR="$pkgdir" install
}
sha512sums=('734745743b2d5fe39f3d6716f377e6255d6a061e3c615a4fe30db388ec6d848f6db063d733dfa24ccf967f1e9042841bce4824f4bed391952c4304ee11e11b0d'
            '1c53f057ce19afcec15e3efa76aad310dc89bf14be7779c59066fd7389744198ae0008ea17c9ca23c1d5be93a8f5bbe1772c7da56fbce99a276260d59bb9f42a')