# Contributor (Arch)    : Maarten van Gompel <proycon at anaproy dot nl>
# Contributor (Arch)    : Lex Black <autumn-wind at web dot de>
# Contributor (Arch)    : Dieter_be
# Maintainer (Parabola) : Aurélien DESBRIÈRES <aurelien@hackers.camp>

_pkgbase=gensim
pkgbase=python-gensim
pkgname=('python-gensim' 'python2-gensim')
pkgver=0.10.3
pkgrel=1
pkgdesc="Python framework for fast Vector Space Modelling"
arch=('i686' 'x86_64')
url="http://nlp.fi.muni.cz/projekty/gensim/"
license=('LGPL')
makedepends=('python-setuptools' 'python2-setuptools' 'python-scipy' 'python2-scipy' 'cython' 'cython2')
source=("http://pypi.python.org/packages/source/g/$_pkgbase/$_pkgbase-${pkgver}.tar.gz")
md5sums=('0a9c0986d9b6c1d3f88135afa3da2230')


prepare() {
    cp -r $_pkgbase-$pkgver $_pkgbase-$pkgver-py2
}

build() {
    unset LDFLAGS
    unset FFLAGS

    cd ${srcdir}/$_pkgbase-${pkgver}
    python setup.py build

    cd ${srcdir}/$_pkgbase-${pkgver}-py2
    python2 setup.py build
}

#test() {
#    python2 setup.py test
#}

package_python-gensim() {
    pkgdesc+=" (Python3.x)"
    depends=(python-scipy)

    cd ${srcdir}/$_pkgbase-${pkgver}
    python setup.py install --prefix=/usr --root=${pkgdir}
}

package_python2-gensim() {
    pkgdesc+=" (Python2.x)"
    depends=(python2-scipy)

    cd ${srcdir}/$_pkgbase-${pkgver}-py2
    python2 setup.py install --prefix=/usr --root=${pkgdir}
}