# Maintainer (Arch): Jiachen Yang <farseerfc@gmail.com>
# Maintainer (Arch): Vlad M. <vlad@archlinux.net>
# Contributor (Arch): Håvard Pettersson <mail@haavard.me>
# Contributor (Arch): Kevin MacMartin <prurigro at gmail dot com>
# Maintainer: André Silva <emulatorman@parabola.nu>

_pkgname=qtox
pkgname=qtox-git
pkgver=r4569.edc35ba
_gitver=edc35ba9dfce0eae1557016933147c926f04a22d
pkgrel=1
pkgdesc='Powerful Tox client written in C++/Qt that follows the Tox design guidelines.'
arch=('i686' 'x86_64''armv7h')
url='https://github.com/tux3/qTox'
license=('GPL3')
depends=('desktop-file-utils'
         'libfilteraudio'
         'libxkbcommon-x11'
         'libxss'
         'openal'
         'opencv'
         'qrencode'
         'qt5-svg'
         'sqlcipher'
         'toxcore')
makedepends=('git' 'qt5-tools')
provides=("$_pkgname")
conflicts=("$_pkgname")
install=$pkgname.install
source=("$_pkgname::git+https://github.com/tux3/qTox.git/#commit=$_gitver")
sha512sums=('SKIP')

pkgver() {
  cd $_pkgname
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
  cd $_pkgname

  # fixing qtox desktop icon and avoid conflict with status icon
  sed -i "s/Icon=qtox/Icon=qTox/" qTox.desktop

  install -d build
  cd build
  qmake-qt5 ENABLE_SYSTRAY_UNITY_BACKEND=NO ..
  make
}

package() {
  cd $_pkgname/build
  make INSTALL_ROOT="$pkgdir" install
}