# Maintainer: Vladimir Tsanev <tsachev@gmail.com>

pkgname=rfc5766-turn-server
_portname=turnserver
pkgver=1.8.6.0
pkgrel=2
epoch=
pkgdesc="Free open source implementation of TURN and STUN Server"
arch=('i686' 'x86_64' 'mips64el')
url="http://code.google.com/p/rfc5766-turn-server/"
license=('custom:BSDNew')
makedepends=('gcc>=3.4.4' 'make' 'hiredis' 'postgresql-libs' 'libmariadbclient')
depends=('libevent')
optdepends=('postgresql-client: to use postgresql'
            'mariadb: mariadb backend'
            'redis: redis backend')
backup=("etc/turnserver.conf" "etc/turnuserdb.conf")
changelog=ChangeLog
source=(https://${pkgname}.googlecode.com/files/${_portname}-$pkgver.tar.gz
        turn.service stun.service)

build() {
  cd "${srcdir}/$_portname-${pkgver}"
  
  PREFIX=/usr \
  MANPREFIX=/usr/share \
  EXAMPLESDIR="/usr/share/$pkgname/examples" \
  DOCSDIR="/usr/share/doc/$pkgname" \
  LIBDIR=/usr/lib \
  SCHEMADIR="/usr/share/$pkgname" \
  TURNINCLUDEDIR="/usr/include/turn"
  ./configure

  make
}

check() {
  cd "${srcdir}/$_portname-${pkgver}"
  make check
}

package() {
  cd "${srcdir}/$_portname-${pkgver}"
  make \
    PREFIX="$pkgdir/usr" \
    MANPREFIX="$pkgdir/usr/share" \
    EXAMPLESDIR="$pkgdir/usr/share/$pkgname/examples" \
    DOCSDIR="$pkgdir/usr/share/doc/$pkgname" \
    LIBDIR="$pkgdir/usr/lib" \
    SCHEMADIR="$pkgdir/usr/share/$pkgname" \
    TURNINCLUDEDIR="$pkgdir/usr/include/turn" \
    install
  
  
  install -D "$pkgdir/usr/share/$pkgname/examples/etc/turnserver.conf" \
             "$pkgdir/etc/turnserver.conf"
  install -D "$pkgdir/usr/share/$pkgname/examples/etc/turnuserdb.conf" \
             "$pkgdir/etc/turnuserdb.conf"
  install -D "$srcdir/stun.service" \
             "$pkgdir/usr/lib/systemd/system/stun.service"
  install -D "$srcdir/turn.service" \
             "$pkgdir/usr/lib/systemd/system/turn.service"
  rm -r "$pkgdir/usr/etc"

  chmod 644 "$pkgdir/usr/lib/libturnclient.a"

  install -Dm 644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
}
md5sums=('def4cc2ea6239795edab12b5eee5f8ed'
         '1da26c3a1fe29a8961e6b9d73f9048d3'
         '83670d79026c67c7701481ee9d39f100')