split up grp-{hostname,locale}, grp-resolve/systemd-resolve{,d}; shell completion

6 files changed, 0 insertions, 711 deletions

diff --git a/shell-completion/zsh/.gitignore b/shell-completion/zsh/.gitignore
deleted file mode 100644
index 75f13ad6d1..0000000000
--- a/shell-completion/zsh/.gitignore
+++ /dev/null
@@ -1 +0,0 @@
-/_systemctl
diff --git a/shell-completion/zsh/_hostnamectl b/shell-completion/zsh/_hostnamectl
deleted file mode 100644
index 7528e0649d..0000000000
--- a/shell-completion/zsh/_hostnamectl
+++ /dev/null
@@ -1,80 +0,0 @@
-#compdef hostnamectl
-
-_hostnamectl_set-hostname() {
-    if (( CURRENT <= 3 )); then
-        _message "new hostname"
-    else
-        _message "no more options"
-    fi
-}
-
-_hostnamectl_set-icon-name() {
-    if (( CURRENT <= 3 )); then
-        _message "new icon name"
-    else
-        _message "no more options"
-    fi
-}
-
-_hostnamectl_set-chassis() {
-    if (( CURRENT <= 3 )); then
-        _chassis=( desktop laptop server tablet handset watch embedded vm container )
-        _describe chassis _chassis
-    else
-        _message "no more options"
-    fi
-}
-
-_hostnamectl_set-deployment() {
-    if (( CURRENT <= 3 )); then
-        _message "new environment"
-    else
-        _message "no more options"
-    fi
-}
-
-_hostnamectl_set-location() {
-    if (( CURRENT <= 3 )); then
-        _message "new location"
-    else
-        _message "no more options"
-    fi
-}
-
-_hostnamectl_command() {
-    local -a _hostnamectl_cmds
-    _hostnamectl_cmds=(
-        "status:Show current hostname settings"
-        "set-hostname:Set system hostname"
-        "set-icon-name:Set icon name for host"
-        "set-chassis:Set chassis type for host"
-        "set-deployment:Set deployment environment for host"
-        "set-location:Set location for host"
-    )
-    if (( CURRENT == 1 )); then
-        _describe -t commands 'hostnamectl commands' _hostnamectl_cmds || compadd "$@"
-    else
-        local curcontext="$curcontext"
-        cmd="${${_hostnamectl_cmds[(r)$words[1]:*]%%:*}}"
-        if (( $#cmd )); then
-            if [[ $cmd == status ]]; then
-                _message "no options"
-            else
-                _hostnamectl_$cmd
-            fi
-        else
-            _message "unknown hostnamectl command: $words[1]"
-        fi
-    fi
-}
-
-_arguments -s \
-    {-h,--help}'[Show this help]' \
-    '--version[Show package version]' \
-    '--transient[Only set transient hostname]' \
-    '--static[Only set static hostname]' \
-    '--pretty[Only set pretty hostname]' \
-    '--no-ask-password[Do not prompt for password]' \
-    {-H+,--host=}'[Operate on remote host]:userathost:_sd_hosts_or_user_at_host' \
-    {-M+,--machine=}'[Operate on local container]:machines:_sd_machines' \
-    '*::hostnamectl commands:_hostnamectl_command'
diff --git a/shell-completion/zsh/_localectl b/shell-completion/zsh/_localectl
deleted file mode 100644
index d8af4d1863..0000000000
--- a/shell-completion/zsh/_localectl
+++ /dev/null
@@ -1,93 +0,0 @@
-#compdef localectl
-
-_localectl_set-locale() {
-    local -a _locales locale_fields
-    locale_fields=(LANG LANGUAGE LC_CTYPE LC_NUMERIC LC_TIME \
-                   LC_COLLATE LC_MONETARY LC_MESSAGES LC_PAPER \
-                   LC_NAME LC_ADDRESS LC_TELEPHONE \
-                   LC_MEASUREMENT LC_IDENTIFICATION)
-    # LC_ALL is omitted on purpose
-
-    local expl suf
-    _locales=( ${(f)"$(_call_program locales "$service" list-locales)"} )
-    compset -P1 '*='
-    if [[ -prefix 1 *\= ]]; then
-        local conf=${PREFIX%%\=*}
-        _wanted locales expl "locales configs" \
-            _combination localeconfs  confs=$conf locales "$@" -
-    else
-        compadd -S '=' $locale_fields
-    fi
-}
-
-_localectl_set-keymap() {
-    local -a _keymaps
-    if (( CURRENT <= 3 )); then
-        _keymaps=( ${(f)"$(_call_program locales "$service" list-keymaps)"} )
-        _describe keymaps _keymaps
-    else
-        _message "no more options"
-    fi
-}
-
-_localectl_set-x11-keymap() {
-    if (( $+commands[pkg-config] )); then
-        local -a _file _layout _model _variant _options
-        local _xorg_lst
-        _xorg_lst=${"$($commands[pkg-config] xkeyboard-config --variable=xkb_base)"}
-        _file=( ${(ps:\n\!:)"$(<$_xorg_lst/rules/xorg.lst)"} )
-        _layout=( ${${${(M)${(f)_file[1]}:#  *}#  }%% *} )
-        _model=( ${${${(M)${(f)_file[2]}:#  *}#  }%% *} )
-        _variant=( ${${${(M)${(f)_file[3]}:#  *}#  }%% *} )
-        _options=( ${${${(M)${(f)_file[4]}:#  *}#  }%% *} )
-        #_layout=( ${(f)"$( echo $_file[1] | awk '/^  / {print $1}' )"} )
-        #_model=( ${(f)"$(echo $_file[2] | awk '/^  / {print $1}')"} )
-        #_variant=( ${(f)"$(echo $_file[3] | awk '/^  / {print $1}')"} )
-        #_options=( ${(f)"$(echo ${_file[4]//:/\\:} | awk '/^  / {print $1}')"} )
-
-        case $CURRENT in
-            2) _describe layouts _layout ;;
-            3) _describe models _model;;
-            4) _describe variants _variant;;
-            5) _describe options _options;;
-            *) _message "no more options"
-        esac
-    fi
-}
-
-_localectl_command() {
-    local -a _localectl_cmds
-    _localectl_cmds=(
-        'status:Show current locale settings'
-        'set-locale:Set system locale'
-        'list-locales:Show known locales'
-        'set-keymap:Set virtual console keyboard mapping'
-        'list-keymaps:Show known virtual console keyboard mappings'
-        'set-x11-keymap:Set X11 keyboard mapping'
-        'list-x11-keymap-models:Show known X11 keyboard mapping models'
-        'list-x11-keymap-layouts:Show known X11 keyboard mapping layouts'
-        'list-x11-keymap-variants:Show known X11 keyboard mapping variants'
-        'list-x11-keymap-options:Show known X11 keyboard mapping options'
-    )
-    if (( CURRENT == 1 )); then
-        _describe -t commands 'localectl command' _localectl_cmds
-    else
-        local curcontext="$curcontext"
-        cmd="${${_localectl_cmds[(r)$words[1]:*]%%:*}}"
-        if (( $+functions[_localectl_$cmd] )); then
-            _localectl_$cmd
-        else
-            _message "unknown localectl command: $words[1]"
-        fi
-    fi
-}
-
-_arguments \
-    {-h,--help}'[Show this help]' \
-    '--version[Show package version]' \
-    "--no-convert[Don't convert keyboard mappings]" \
-    '--no-pager[Do not pipe output into a pager]' \
-    '--no-ask-password[Do not prompt for password]' \
-    {-H+,--host=}'[Operate on remote host]:userathost:_sd_hosts_or_user_at_host' \
-    {-M+,--machine=}'[Operate on local container]:machine' \
-    '*::localectl commands:_localectl_command'
diff --git a/shell-completion/zsh/_systemctl.in b/shell-completion/zsh/_systemctl.in
deleted file mode 100644
index 44c31b7833..0000000000
--- a/shell-completion/zsh/_systemctl.in
+++ /dev/null
@@ -1,391 +0,0 @@
-#compdef systemctl
-
-(( $+functions[_systemctl_command] )) || _systemctl_command()
-{
-  local -a _systemctl_cmds
-  _systemctl_cmds=(
-    "list-sockets:List sockets"
-    "list-timers:List timers"
-    "list-units:List units"
-    "start:Start (activate) one or more units"
-    "stop:Stop (deactivate) one or more units"
-    "reload:Reload one or more units"
-    "restart:Start or restart one or more units"
-    "condrestart:Restart one or more units if active"
-    "try-restart:Restart one or more units if active"
-    "reload-or-restart:Reload one or more units if possible, otherwise start or restart"
-    "force-reload:Reload one or more units if possible, otherwise restart if active"
-    "hibernate:Hibernate the system"
-    "hybrid-sleep:Hibernate and suspend the system"
-    "try-reload-or-restart:Reload one or more units if possible, otherwise restart if active"
-    "isolate:Start one unit and stop all others"
-    "kill:Send signal to processes of a unit"
-    "is-active:Check whether units are active"
-    "is-failed:Check whether units are failed"
-    "status:Show runtime status of one or more units"
-    "show:Show properties of one or more units/jobs or the manager"
-    "cat:Show the source unit files and drop-ins"
-    "reset-failed:Reset failed state for all, one, or more units"
-    "list-unit-files:List installed unit files"
-    "enable:Enable one or more unit files"
-    "disable:Disable one or more unit files"
-    "reenable:Reenable one or more unit files"
-    "preset:Enable/disable one or more unit files based on preset configuration"
-    "set-default:Set the default target"
-    "get-default:Query the default target"
-    "edit:Edit one or more unit files"
-    "is-system-running:Query overall status of the system"
-    "help:Show documentation for specified units"
-    "list-dependencies:Show unit dependency tree"
-    "mask:Mask one or more units"
-    "unmask:Unmask one or more units"
-    "link:Link one or more units files into the search path"
-    "is-enabled:Check whether unit files are enabled"
-    "list-jobs:List jobs"
-    "cancel:Cancel all, one, or more jobs"
-    "show-environment:Dump environment"
-    "set-environment:Set one or more environment variables"
-    "unset-environment:Unset one or more environment variables"
-    "daemon-reload:Reload systemd manager configuration"
-    "daemon-reexec:Reexecute systemd manager"
-    "default:Enter system default mode"
-    "rescue:Enter system rescue mode"
-    "emergency:Enter system emergency mode"
-    "halt:Shut down and halt the system"
-    "suspend:Suspend the system"
-    "poweroff:Shut down and power-off the system"
-    "reboot:Shut down and reboot the system"
-    "kexec:Shut down and reboot the system with kexec"
-    "exit:Ask for user instance termination"
-    "switch-root:Change root directory"
-  )
-
-  if (( CURRENT == 1 )); then
-    _describe -t commands 'systemctl command' _systemctl_cmds || compadd "$@"
-  else
-    local curcontext="$curcontext" expl
-
-    cmd="${${_systemctl_cmds[(r)$words[1]:*]%%:*}}"
-    # Deal with any aliases
-    case $cmd in
-      condrestart) cmd="try-restart";;
-      force-reload) cmd="try-reload-or-restart";;
-    esac
-
-    if (( $#cmd )); then
-      curcontext="${curcontext%:*:*}:systemctl-${cmd}:"
-
-      local update_policy
-      zstyle -s ":completion:${curcontext}:" cache-policy update_policy
-      if [[ -z "$update_policy" ]]; then
-        zstyle ":completion:${curcontext}:" cache-policy _systemctl_caching_policy
-      fi
-
-      _call_function ret _systemctl_$cmd || _message 'no more arguments'
-    else
-      _message "unknown systemctl command: $words[1]"
-    fi
-    return ret
-  fi
-}
-
-__systemctl()
-{
-  systemctl $_sys_service_mgr --full --no-legend --no-pager "$@"
-}
-
-
-# Fills the unit list
-_systemctl_all_units()
-{
-  if ( [[ ${+_sys_all_units} -eq 0 ]] || _cache_invalid SYS_ALL_UNITS ) &&
-    ! _retrieve_cache SYS_ALL_UNITS;
-  then
-    _sys_all_units=( ${${(f)"$(__systemctl list-units --all)"}%% *} )
-    _store_cache SYS_ALL_UNITS _sys_all_units
-  fi
-}
-
-# Fills the unit list including all file units
-_systemctl_really_all_units()
-{
-  local -a all_unit_files;
-  local -a really_all_units;
-  if ( [[ ${+_sys_really_all_units} -eq 0 ]] || _cache_invalid SYS_REALLY_ALL_UNITS ) &&
-    ! _retrieve_cache SYS_REALLY_ALL_UNITS;
-  then
-    all_unit_files=( ${${(f)"$(__systemctl list-unit-files)"}%% *} )
-    _systemctl_all_units
-    really_all_units=($_sys_all_units $all_unit_files)
-    _sys_really_all_units=(${(u)really_all_units})
-    _store_cache SYS_REALLY_ALL_UNITS _sys_really_all_units
-  fi
-}
-
-_filter_units_by_property() {
-  local property=$1 value=$2 ; shift ; shift
-  local -a units ; units=($*)
-  local props
-  for props in ${(ps:\n\n:)"$(_call_program units "$service show --no-pager --property="Id,$property" -- ${units} 2>/dev/null")"}; do
-    props=(${(f)props})
-    if [[ "${props[2]}" = "$property=$value" ]]; then
-      echo -E - " ${props[1]#Id=}"
-    fi
-  done
-}
-
-_systemctl_get_template_names() { echo -E - ${^${(M)${(f)"$(__systemctl list-unit-files)"}##*@.[^[:space:]]##}%%@.*}\@ }
-
-
-_systemctl_active_units()  {_sys_active_units=(  ${${(f)"$(__systemctl list-units)"}%% *} )}
-
-_systemctl_startable_units(){
-    _sys_startable_units=( $( _filter_units_by_property ActiveState inactive $(
-                          _filter_units_by_property CanStart yes $(
-                          __systemctl $mode list-unit-files --state enabled,disabled,static | \
-                               { while read -r a b; do [[ $a =~ @\. ]] || echo -E - " $a"; done; }
-                          __systemctl $mode list-units --state inactive,failed | \
-                               { while read -r a b; do echo -E - " $a"; done; } )) ) )
-}
-
-_systemctl_restartable_units(){
-    _sys_restartable_units=( $(_filter_units_by_property CanStart yes $(
-                          __systemctl $mode list-unit-files --state enabled,disabled,static | \
-                               { while read -r a b; do [[ $a =~ @\. ]] || echo -E - " $a"; done; }
-                          __systemctl $mode list-units | \
-                               { while read -r a b; do echo -E - " $a"; done; } )) )
-}
-
-_systemctl_failed_units()  {_sys_failed_units=( ${${(f)"$(__systemctl list-units --state=failed)"}%% *} ) }
-_systemctl_unit_state() { typeset -gA _sys_unit_state; _sys_unit_state=( $(__systemctl list-unit-files) ) }
-
-local fun
-# Completion functions for ALL_UNITS
-for fun in is-active is-failed is-enabled status show cat mask preset help list-dependencies edit ; do
-  (( $+functions[_systemctl_$fun] )) || _systemctl_$fun()
-  {
-    _systemctl_really_all_units
-    _wanted systemd-units expl unit \
-      compadd "$@" -a - _sys_really_all_units
-  }
-done
-
-# Completion functions for ENABLED_UNITS
-(( $+functions[_systemctl_disable] )) || _systemctl_disable()
-{
-    local _sys_unit_state; _systemctl_unit_state
-    _wanted systemd-units expl 'enabled unit' \
-      compadd "$@" - ${(k)_sys_unit_state[(R)enabled]}
-}
-
-(( $+functions[_systemctl_reenable] )) || _systemctl_reenable()
-{
-    local _sys_unit_state; _systemctl_unit_state
-    _wanted systemd-units expl 'enabled/disabled unit' \
-      compadd "$@" - ${(k)_sys_unit_state[(R)(enabled|disabled)]} $(_systemctl_get_template_names)
-}
-
-# Completion functions for DISABLED_UNITS
-(( $+functions[_systemctl_enable] )) || _systemctl_enable()
-{
-  local _sys_unit_state; _systemctl_unit_state
-  _wanted systemd-units expl 'disabled unit' \
-    compadd "$@" - ${(k)_sys_unit_state[(R)disabled]} $(_systemctl_get_template_names)
-}
-
-# Completion functions for FAILED_UNITS
-(( $+functions[_systemctl_reset-failed] )) || _systemctl_reset-failed()
-{
-  local _sys_failed_units; _systemctl_failed_units
-  _wanted systemd-units expl 'failed unit' \
-    compadd "$@" -a - _sys_failed_units || _message "no failed unit found"
-}
-
-# Completion functions for STARTABLE_UNITS
-(( $+functions[_systemctl_start] )) || _systemctl_start()
-{
-   local _sys_startable_units; _systemctl_startable_units
-   _wanted systemd-units expl 'startable unit' \
-     compadd "$@" - ${_sys_startable_units[*]} $(_systemctl_get_template_names)
-}
-
-# Completion functions for STOPPABLE_UNITS
-for fun in stop kill try-restart condrestart ; do
-  (( $+functions[_systemctl_$fun] )) || _systemctl_$fun()
-  {
-    local _sys_active_units; _systemctl_active_units
-    _wanted systemd-units expl 'stoppable unit' \
-      compadd "$@" - $( _filter_units_by_property CanStop yes \
-        ${_sys_active_units[*]} )
-  }
-done
-
-# Completion functions for ISOLATABLE_UNITS
-(( $+functions[_systemctl_isolate] )) || _systemctl_isolate()
-{
-  _systemctl_all_units
-  _wanted systemd-units expl 'isolatable unit' \
-    compadd "$@" - $( _filter_units_by_property AllowIsolate yes \
-      ${_sys_all_units[*]} )
-}
-
-# Completion functions for RELOADABLE_UNITS
-for fun in reload try-reload-or-restart force-reload ; do
-  (( $+functions[_systemctl_$fun] )) || _systemctl_$fun()
-  {
-    local _sys_active_units; _systemctl_active_units
-    _wanted systemd-units expl 'reloadable unit' \
-      compadd "$@" - $( _filter_units_by_property CanReload yes \
-        ${_sys_active_units[*]} )
-  }
-done
-
-# Completion functions for RESTARTABLE_UNITS
-for fun in restart reload-or-restart ; do
-  (( $+functions[_systemctl_$fun] )) || _systemctl_$fun()
-  {
-    local _sys_restartable_units; _systemctl_restartable_units
-    _wanted systemd-units expl 'restartable unit' \
-      compadd "$@" - ${_sys_restartable_units[*]} $(_systemctl_get_template_names)
-  }
-done
-
-# Completion functions for MASKED_UNITS
-(( $+functions[_systemctl_unmask] )) || _systemctl_unmask()
-{
-  local _sys_unit_state; _systemctl_unit_state
-  _wanted systemd-units expl 'masked unit' \
-    compadd "$@" - ${(k)_sys_unit_state[(R)masked]} || _message "no masked units found"
-}
-
-# Completion functions for JOBS
-(( $+functions[_systemctl_cancel] )) || _systemctl_cancel()
-{
-  _wanted systemd-jobs expl job \
-    compadd "$@" - ${${(f)"$(__systemctl list-jobs)"}%% *} ||
-      _message "no jobs found"
-}
-
-# Completion functions for TARGETS
-(( $+functions[_systemctl_set-default] )) || _systemctl_set-default()
-{
-  _wanted systemd-targets expl target \
-    compadd "$@" - ${${(f)"$(__systemctl list-unit-files --type target --all)"}%% *} ||
-      _message "no targets found"
-}
-
-# Completion functions for ENVS
-for fun in set-environment unset-environment ; do
-  (( $+functions[_systemctl_$fun] )) || _systemctl_$fun()
-  {
-    local fun=$0 ; fun=${fun##_systemctl_}
-    local suf
-    if [[ "${fun}" = "set-environment" ]]; then
-      suf='-S='
-    fi
-    _wanted systemd-environment expl 'environment variable' \
-      compadd "$@" ${suf} - ${${(f)"$(systemctl show-environment)"}%%=*}
-  }
-done
-
-(( $+functions[_systemctl_link] )) || _systemctl_link() {
-   _sd_unit_files
-}
-
-(( $+functions[_systemctl_switch-root] )) || _systemctl_switch-root() {
-   _files
-}
-
-# no systemctl completion for:
-#    [STANDALONE]='daemon-reexec daemon-reload default
-#                  emergency exit halt kexec list-jobs list-units
-#                  list-unit-files poweroff reboot rescue show-environment'
-
-_systemctl_caching_policy()
-{
-  local _sysunits
-  local -a oldcache
-
-  # rebuild if cache is more than a day old
-  oldcache=( "$1"(mh+1) )
-  (( $#oldcache )) && return 0
-
-  _sysunits=(${${(f)"$(__systemctl --all)"}%% *})
-
-  if (( $#_sysunits )); then
-    for unit in $_sysunits; do
-      [[ "$unit" -nt "$1" ]] && return 0
-    done
-  fi
-
-  return 1
-}
-
-_unit_states() {
-    local -a _states
-    _states=("${(fo)$(__systemctl --state=help)}")
-    _values -s , "${_states[@]}"
-}
-
-_unit_types() {
-    local -a _types
-    _types=("${(fo)$(__systemctl -t help)}")
-    _values -s , "${_types[@]}"
-}
-
-_unit_properties() {
-  if ( [[ ${+_sys_all_properties} -eq 0 ]] || _cache_invalid SYS_ALL_PROPERTIES ) &&
-    ! _retrieve_cache SYS_ALL_PROPERTIES;
-  then
-    _sys_all_properties=( ${${(M)${(f)"$(__systemctl show --all;
-    @rootlibexecdir@/systemd --dump-configuration-items)"}##[[:alnum:]]##=*}%%=*}
-    )
-    _store_cache SYS_ALL_PROPRTIES _sys_all_properties
-  fi
-  _values -s , "${_sys_all_properties[@]}"
-}
-
-_job_modes() {
-    local -a _modes
-    _modes=(fail replace replace-irreversibly isolate ignore-dependencies ignore-requirements flush)
-    _values -s , "${_modes[@]}"
-}
-
-local -a _modes; _modes=("--user" "--system")
-local _sys_service_mgr=${${words:*_modes}[(R)(${(j.|.)_modes})]:---system}
-_arguments -s \
-    {-h,--help}'[Show help]' \
-    '--version[Show package version]' \
-    {-t+,--type=}'[List only units of a particular type]:unit type:_unit_types' \
-    '--state=[Display units in the specified state]:unit state:_unit_states' \
-    '--job-mode=[Specify how to deal with other jobs]:mode:_job_modes' \
-    {-p+,--property=}'[Show only properties by specific name]:unit property:_unit_properties' \
-    {-a,--all}'[Show all units/properties, including dead/empty ones]' \
-    '--reverse[Show reverse dependencies]' \
-    '--after[Show units ordered after]' \
-    '--before[Show units ordered before]' \
-    {-l,--full}"[Don't ellipsize unit names on output]" \
-    '--show-types[When showing sockets, show socket type]' \
-    {-i,--ignore-inhibitors}'[When executing a job, ignore jobs dependencies]' \
-    {-q,--quiet}'[Suppress output]' \
-    '--no-block[Do not wait until operation finished]' \
-    '--no-legend[Do not print a legend, i.e. the column headers and the footer with hints]' \
-    '--no-pager[Do not pipe output into a pager]' \
-    '--system[Connect to system manager]' \
-    '--user[Connect to user service manager]' \
-    "--no-wall[Don't send wall message before halt/power-off/reboot]" \
-    '--global[Enable/disable unit files globally]' \
-    "--no-reload[When enabling/disabling unit files, don't reload daemon configuration]" \
-    '--no-ask-password[Do not ask for system passwords]' \
-    '--kill-who=[Who to send signal to]:killwho:(main control all)' \
-    {-s+,--signal=}'[Which signal to send]:signal:_signals' \
-    {-f,--force}'[When enabling unit files, override existing symlinks. When shutting down, execute action immediately]' \
-    '--root=[Enable unit files in the specified root directory]:directory:_directories' \
-    '--runtime[Enable unit files only temporarily until next reboot]' \
-    {-H+,--host=}'[Operate on remote host]:userathost:_sd_hosts_or_user_at_host' \
-    {-P,--privileged}'[Acquire privileges before execution]' \
-    {-n+,--lines=}'[Journal entries to show]:number of entries' \
-    {-o+,--output=}'[Change journal output mode]:modes:_sd_outputmodes' \
-    '--firmware-setup[Tell the firmware to show the setup menu on next boot]' \
-    '--plain[When used with list-dependencies, print output as a list]' \
-    '*::systemctl command:_systemctl_command'
diff --git a/shell-completion/zsh/_systemd b/shell-completion/zsh/_systemd
deleted file mode 100644
index 62114ff095..0000000000
--- a/shell-completion/zsh/_systemd
+++ /dev/null
@@ -1,82 +0,0 @@
-#compdef systemd-cat systemd-ask-password systemd-cgls systemd-cgtop systemd-detect-virt systemd-machine-id-setup systemd-notify systemd-tty-ask-password-agent
-
-local curcontext="$curcontext" state lstate line
-case "$service" in
-    systemd-ask-password)
-        _arguments \
-            {-h,--help}'[Show this help]' \
-            '--icon=[Icon name]:icon name:' \
-            '--timeout=[Timeout in sec]:timeout (seconds):' \
-            '--no-tty[Ask question via agent even on TTY]' \
-            '--accept-cached[Accept cached passwords]' \
-            '--multiple[List multiple passwords if available]'
-    ;;
-    systemd-cat)
-        _arguments \
-            {-h,--help}'[Show this help]' \
-            '--version[Show package version.]' \
-            {-t+,--identifier=}'[Set syslog identifier.]:syslog identifier:' \
-            {-p+,--priority=}'[Set priority value.]:value:({0..7})' \
-            '--level-prefix=[Control whether level prefix shall be parsed.]:boolean:(1 0)' \
-            ':Message'
-    ;;
-    systemd-cgls)
-        _arguments \
-            {-h,--help}'[Show this help]' \
-            '--version[Show package version]' \
-            '--no-pager[Do not pipe output into a pager]' \
-            {-a,--all}'[Show all groups, including empty]' \
-            '-k[Include kernel threads in output]' \
-            ':cgroups:(cpuset cpu cpuacct memory devices freezer blkio)'
-    ;;
-    systemd-cgtop)
-        _arguments \
-            {-h,--help}'[Show this help]' \
-            '--version[Print version and exit]' \
-            '(-c -m -i -t)-p[Order by path]' \
-            '(-c -p -m -i)-t[Order by number of tasks]' \
-            '(-m -p -i -t)-c[Order by CPU load]' \
-            '(-c -p -i -t)-m[Order by memory load]' \
-            '(-c -m -p -t)-i[Order by IO load]' \
-            {-d+,--delay=}'[Specify delay]:delay:' \
-            {-n+,--iterations=}'[Run for N iterations before exiting]:number of iterations:' \
-            {-b,--batch}'[Run in batch mode, accepting no input]' \
-            '--depth=[Maximum traversal depth]:maximum depth:'
-    ;;
-    systemd-detect-virt)
-        _arguments \
-            {-h,--help}'[Show this help]' \
-            '--version[Show package version]' \
-            {-c,--container}'[Only detect whether we are run in a container]' \
-            {-v,--vm}'[Only detect whether we are run in a VM]' \
-            {-q,--quiet}"[Don't output anything, just set return value]"
-    ;;
-    systemd-machine-id-setup)
-        _arguments \
-            {-h,--help}'[Show this help]' \
-            '--version[Show package version]'
-    ;;
-    systemd-notify)
-        _arguments \
-            {-h,--help}'[Show this help]' \
-            '--version[Show package version]' \
-            '--ready[Inform the init system about service start-up completion.]' \
-            '--pid=[Inform the init system about the main PID of the daemon]:daemon main PID:_pids' \
-            '--status=[Send a free-form status string for the daemon to the init systemd]:status string:' \
-            '--booted[Returns 0 if the system was booted up with systemd]'
-    ;;
-    systemd-tty-ask-password-agent)
-        _arguments \
-            {-h,--help}'[Prints a short help text and exits.]' \
-            '--version[Prints a short version string and exits.]' \
-            '--list[Lists all currently pending system password requests.]' \
-            '--query[Process all currently pending system password requests by querying the user on the calling TTY.]' \
-            '--watch[Continuously process password requests.]' \
-            '--wall[Forward password requests to wall(1).]' \
-            '--plymouth[Ask question with plymouth(8).]' \
-            '--console[Ask question on /dev/console.]'
-    ;;
-    *) _message 'eh?' ;;
-esac
-
-#vim: set ft=zsh sw=4 ts=4 et
diff --git a/shell-completion/zsh/_systemd-resolve b/shell-completion/zsh/_systemd-resolve
deleted file mode 100644
index c318ab50f1..0000000000
--- a/shell-completion/zsh/_systemd-resolve
+++ /dev/null
@@ -1,64 +0,0 @@
-#compdef systemd-resolve
-
-#
-# This file is part of systemd.
-#
-# Copyright 2016 Zbigniew Jędrzejewski-Szmek
-#
-# systemd is free software; you can redistribute it and/or modify it
-# under the terms of the GNU Lesser General Public License as published by
-# the Free Software Foundation; either version 2.1 of the License, or
-# (at your option) any later version.
-#
-# systemd is distributed in the hope that it will be useful, but
-# WITHOUT ANY WARRANTY; without even the implied warranty of
-# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
-# General Public License for more details.
-#
-# You should have received a copy of the GNU Lesser General Public License
-# along with systemd; If not, see <http://www.gnu.org/licenses/>.
-
-_dns_protocol() {
-    local -a _protocol
-    _protocol=( $(_call_program protocol ${service} --legend=no --protocol help; echo help) )
-    _values 'protocol' "$_protocol[@]"
-}
-
-_dns_type() {
-    local -a _type
-    _type=( $(_call_program type ${service} --legend=no --type help; echo help) )
-    _values 'type' "$_type[@]"
-}
-
-_dns_class() {
-    local -a _class
-    _class=( $(_call_program class ${service} --legend=no --class help; echo help) )
-    _values 'class' "$_class[@]"
-}
-
-_systemd-resolve_none() {
-    _alternative : \
-        'domain:DNS address:' \
-        'address:email address:'
-}
-
-_arguments \
-    {-h,--help}'[Print a short help text and exit]' \
-    '--version[Print a short version string and exit]' \
-    '--legend=no[Do not show headers and footers]' \
-    '-4[Resolve IPv4 addresses]' \
-    '-6[Resolve IPv6 addresses]' \
-    {-i+,--interface=}'[Look on interface]:interface:_net_interfaces' \
-    {-p+,--protocol=}'[Look via protocol]:protocol:_dns_protocol' \
-    {-t+,--type=}'[Query RR with DNS type]:type:_dns_type' \
-    {-c+,--class=}'[Query RR with DNS class]:class:_dns_class' \
-    '--service[Resolve services]' \
-    '--service-address=no[Do not resolve address for services]' \
-    '--service-txt=no[Do not resolve TXT records for services]' \
-    '--openpgp[Query OpenPGP public key]' \
-    '--tlsa[Query TLS public key]' \
-    '--cname=no[Do not follow CNAME redirects]' \
-    '--search=no[Do not use search domains]' \
-    '--statistics[Show resolver statistics]' \
-    '--reset-statistics[Reset resolver statistics]' \
-    '*::default: _systemd-resolve_none'