From 2abe0f2d527c7b3f6b97bd6519bf0e35a266ea68 Mon Sep 17 00:00:00 2001
From: Luke Shumaker <lukeshu@sbcglobal.net>
Date: Sun, 7 Aug 2016 21:03:44 -0400
Subject: stuff

---
 src/busctl/busctl.completion.zsh | 72 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 72 insertions(+)
 create mode 100644 src/busctl/busctl.completion.zsh

(limited to 'src/busctl/busctl.completion.zsh')

diff --git a/src/busctl/busctl.completion.zsh b/src/busctl/busctl.completion.zsh
new file mode 100644
index 0000000000..a425b8c700
--- /dev/null
+++ b/src/busctl/busctl.completion.zsh
@@ -0,0 +1,72 @@
+#compdef busctl
+
+# busctl(1) completion                               -*- shell-script -*-
+#
+# This file is part of systemd.
+#
+# Copyright 2013 Zbigniew Jędrzejewski-Szmek
+#
+# systemd is free software; you can redistribute it and/or modify it
+# under the terms of the GNU Lesser General Public License as published by
+# the Free Software Foundation; either version 2.1 of the License, or
+# (at your option) any later version.
+#
+# systemd is distributed in the hope that it will be useful, but
+# WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+# General Public License for more details.
+#
+# You should have received a copy of the GNU Lesser General Public License
+# along with systemd; If not, see <http://www.gnu.org/licenses/>.
+
+(( $+functions[_busctl_command] )) || _busctl_command()
+{
+    local -a _busctl_cmds
+    _busctl_cmds=(
+        "list:List bus names"
+        "status:Show bus service, process or bus owner credentials"
+        "monitor:Show bus traffic"
+        "capture:Capture bus traffix as pcap"
+        "tree:Show object tree of service"
+        "introspect:Introspect object"
+        "call:Call a method"
+        "get-property:Get property value"
+        "set-property:Set property value"
+    )
+    if (( CURRENT == 1 )); then
+        _describe -t commands 'busctl command' _busctl_cmds || compadd "$@"
+    else
+        local curcontext="$curcontext"
+        cmd="${${_busctl_cmds[(r)$words[1]:*]%%:*}}"
+        if (( $+functions[_busctl_$cmd] )); then
+            _busctl_$cmd
+        else
+            _message "no more options"
+        fi
+    fi
+}
+
+_arguments \
+    {-h,--help}'[Prints a short help text and exits.]' \
+    '--version[Prints a short version string and exits.]' \
+    '--no-pager[Do not pipe output into a pager]' \
+    '--no-legend[Do not show the headers and footers]' \
+    '--system[Connect to system manager]' \
+    '--user[Connect to user service manager]' \
+    {-H+,--host=}'[Operate on remote host]:userathost:_sd_hosts_or_user_at_host' \
+    {-M+,--machine=}'[Operate on local container]:machines:_sd_machines' \
+    '--address=[Connect to the bus specified by address]:address' \
+    '--show-machine[Show machine ID column in list]' \
+    '--unique[Only show unique names]' \
+    '--acquired[Only show acquired names]' \
+    '--activatable[Only show activatable names]' \
+    '--match=[Only show matching messages]:match' \
+    '--list[Do not show tree, but simple object path list]' \
+    '--quiet[Do not show method call reply]'\
+    '--verbose[Show result values in long format]' \
+    '--expect-reply=[Expect a method call reply]:boolean:(1 0)' \
+    '--auto-start=[Auto-start destination service]:boolean:(1 0)' \
+    '--allow-interactive-authorization=[Allow interactive authorization for operation]:boolean:(1 0)' \
+    '--timeout=[Maximum time to wait for method call completion]:timeout (seconds)' \
+    '--augment-creds=[Extend credential data with data read from /proc/$PID]:boolean:(1 0)' \
+    '*::busctl command:_busctl_command'
-- 
cgit v1.2.3-54-g00ecf