From 2abe0f2d527c7b3f6b97bd6519bf0e35a266ea68 Mon Sep 17 00:00:00 2001
From: Luke Shumaker <lukeshu@sbcglobal.net>
Date: Sun, 7 Aug 2016 21:03:44 -0400
Subject: stuff

---
 src/grp-login/loginctl/loginctl.completion.bash    | 111 +++++++++++++
 src/grp-login/loginctl/loginctl.completion.zsh     | 172 +++++++++++++++++++++
 .../systemd-inhibit/systemd-inhibit.completion.zsh |  33 ++++
 3 files changed, 316 insertions(+)
 create mode 100644 src/grp-login/loginctl/loginctl.completion.bash
 create mode 100644 src/grp-login/loginctl/loginctl.completion.zsh
 create mode 100644 src/grp-login/systemd-inhibit/systemd-inhibit.completion.zsh

(limited to 'src/grp-login')

diff --git a/src/grp-login/loginctl/loginctl.completion.bash b/src/grp-login/loginctl/loginctl.completion.bash
new file mode 100644
index 0000000000..776eca4e62
--- /dev/null
+++ b/src/grp-login/loginctl/loginctl.completion.bash
@@ -0,0 +1,111 @@
+# loginctl(1) completion                                  -*- shell-script -*-
+#
+# This file is part of systemd.
+#
+# Copyright 2010 Ran Benita
+#
+# systemd is free software; you can redistribute it and/or modify it
+# under the terms of the GNU Lesser General Public License as published by
+# the Free Software Foundation; either version 2.1 of the License, or
+# (at your option) any later version.
+#
+# systemd is distributed in the hope that it will be useful, but
+# WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
+# General Public License for more details.
+#
+# You should have received a copy of the GNU Lesser General Public License
+# along with systemd; If not, see <http://www.gnu.org/licenses/>.
+
+__contains_word () {
+        local w word=$1; shift
+        for w in "$@"; do
+                [[ $w = "$word" ]] && return
+        done
+}
+
+__get_all_sessions () { loginctl --no-legend list-sessions | { while read -r a b; do printf "%s\n" "$a"; done; } ; }
+__get_all_users    () { loginctl --no-legend list-users    | { while read -r a b; do printf "%s\n" "$b"; done; } ; }
+__get_all_seats    () { loginctl --no-legend list-seats    | { while read -r a b; do printf "%s\n" "$a"; done; } ; }
+
+_loginctl () {
+        local cur=${COMP_WORDS[COMP_CWORD]} prev=${COMP_WORDS[COMP_CWORD-1]}
+        local i verb comps
+
+        local -A OPTS=(
+               [STANDALONE]='--all -a --help -h --no-pager --privileged -P --version
+                             --no-legend --no-ask-password -l --full'
+                      [ARG]='--host -H --kill-who --property -p --signal -s --machine'
+                      )
+
+        if __contains_word "$prev" ${OPTS[ARG]}; then
+                case $prev in
+                        --signal|-s)
+                                _signals
+                                return
+                        ;;
+                        --kill-who)
+                                comps='all leader'
+                        ;;
+                        --host|-H)
+                                comps=$(compgen -A hostname)
+                        ;;
+                        --property|-p)
+                                comps=''
+                        ;;
+                esac
+                COMPREPLY=( $(compgen -W '$comps' -- "$cur") )
+                return 0
+        fi
+
+
+        if [[ "$cur" = -* ]]; then
+                COMPREPLY=( $(compgen -W '${OPTS[*]}' -- "$cur") )
+                return 0
+        fi
+
+        local -A VERBS=(
+                [SESSIONS]='session-status show-session activate lock-session unlock-session terminate-session kill-session'
+                [USERS]='user-status show-user enable-linger disable-linger terminate-user kill-user'
+                [SEATS]='seat-status show-seat terminate-seat'
+                [STANDALONE]='list-sessions list-users list-seats flush-devices'
+                [ATTACH]='attach'
+        )
+
+        for ((i=0; i < COMP_CWORD; i++)); do
+                if __contains_word "${COMP_WORDS[i]}" ${VERBS[*]} &&
+                 ! __contains_word "${COMP_WORDS[i-1]}" ${OPTS[ARG]}; then
+                        verb=${COMP_WORDS[i]}
+                        break
+                fi
+        done
+
+        if   [[ -z $verb ]]; then
+                comps="${VERBS[*]}"
+
+        elif __contains_word "$verb" ${VERBS[SESSIONS]}; then
+                comps=$( __get_all_sessions )
+
+        elif __contains_word "$verb" ${VERBS[USERS]}; then
+                comps=$( __get_all_users )
+
+        elif __contains_word "$verb" ${VERBS[SEATS]}; then
+                comps=$( __get_all_seats )
+
+        elif __contains_word "$verb" ${VERBS[STANDALONE]}; then
+                comps=''
+
+        elif __contains_word "$verb" ${VERBS[ATTACH]}; then
+                if [[ $prev = $verb ]]; then
+                        comps=$( __get_all_seats )
+                else
+                        comps=$(compgen -A file -- "$cur" )
+                        compopt -o filenames
+                fi
+        fi
+
+        COMPREPLY=( $(compgen -W '$comps' -- "$cur") )
+        return 0
+}
+
+complete -F _loginctl loginctl
diff --git a/src/grp-login/loginctl/loginctl.completion.zsh b/src/grp-login/loginctl/loginctl.completion.zsh
new file mode 100644
index 0000000000..6f6ff6e314
--- /dev/null
+++ b/src/grp-login/loginctl/loginctl.completion.zsh
@@ -0,0 +1,172 @@
+#compdef loginctl
+
+_loginctl_all_sessions() {
+  local session description
+  loginctl --no-legend list-sessions | while read -r session description; do
+    _sys_all_sessions+=( "$session" )
+    _sys_all_sessions_descr+=( "${session}:$description" )
+  done
+}
+
+_loginctl_all_users() {
+  local uid description
+  loginctl --no-legend list-users | while read -r uid description; do
+    _sys_all_users+=( "$uid" )
+    _sys_all_users_descr+=( "${uid}:$description" )
+  done
+}
+
+_loginctl_all_seats() {
+  local seat description
+  loginctl --no-legend list-seats | while read -r seat description; do
+    _sys_all_seats+=( "$seat" )
+    _sys_all_seats_descr+=( "${seat}:$description" )
+  done
+}
+
+local fun
+# Completion functions for SESSIONS
+for fun in session-status show-session activate lock-session unlock-session terminate-session kill-session ; do
+  (( $+functions[_loginctl_$fun] )) || _loginctl_$fun()
+  {
+    local -a _sys_all_sessions{,_descr}
+
+    _loginctl_all_sessions
+    for _ignore in $words[2,-1]; do
+      _sys_all_sessions[(i)$_ignore]=()
+      _sys_all_sessions_descr[(i)$_ignore:*]=()
+    done
+
+    if zstyle -T ":completion:${curcontext}:systemd-sessions" verbose; then
+      _describe -t systemd-sessions session _sys_all_sessions_descr _sys_all_sessions "$@"
+    else
+      local expl
+      _wanted systemd-sessions expl session compadd "$@" -a _sys_all_sessions
+    fi
+  }
+done
+
+# Completion functions for USERS
+for fun in user-status show-user enable-linger disable-linger terminate-user kill-user ; do
+  (( $+functions[_loginctl_$fun] )) || _loginctl_$fun()
+  {
+    local -a _sys_all_users{,_descr}
+    zstyle -a ":completion:${curcontext}:users" users _sys_all_users
+
+    if ! (( $#_sys_all_users )); then
+      _loginctl_all_users
+    fi
+
+    for _ignore in $words[2,-1]; do
+      _sys_all_users[(i)$_ignore]=()
+      _sys_all_users_descr[(i)$_ignore:*]=()
+    done
+
+    # using the common tag `users' here, not rolling our own `systemd-users' tag
+    if zstyle -T ":completion:${curcontext}:users" verbose; then
+      _describe -t users user ${_sys_all_users_descr:+_sys_all_users_descr} _sys_all_users "$@"
+    else
+      local expl
+      _wanted users expl user compadd "$@" -a _sys_all_users
+    fi
+  }
+done
+
+# Completion functions for SEATS
+(( $+functions[_loginctl_seats] )) || _loginctl_seats()
+{
+  local -a _sys_all_seats{,_descr}
+
+  _loginctl_all_seats
+  for _ignore in $words[2,-1]; do
+    _sys_all_seats[(i)$_ignore]=()
+    _sys_all_seats_descr[(i)$_ignore:*]=()
+  done
+
+  if zstyle -T ":completion:${curcontext}:systemd-seats" verbose; then
+    _describe -t systemd-seats seat _sys_all_seats_descr _sys_all_seats "$@"
+  else
+    local expl
+    _wanted systemd-seats expl seat compadd "$@" -a _sys_all_seats
+  fi
+}
+for fun in seat-status show-seat terminate-seat ; do
+  (( $+functions[_loginctl_$fun] )) || _loginctl_$fun()
+  { _loginctl_seats }
+done
+
+# Completion functions for ATTACH
+(( $+functions[_loginctl_attach] )) || _loginctl_attach()
+{
+  _arguments -w -C -S -s \
+    ':seat:_loginctl_seats' \
+    '*:device:_files'
+}
+
+# no loginctl completion for:
+# [STANDALONE]='list-sessions list-users list-seats flush-devices'
+
+(( $+functions[_loginctl_command] )) || _loginctl_command()
+{
+  local -a _loginctl_cmds
+  _loginctl_cmds=(
+    "list-sessions:List sessions"
+    "session-status:Show session status"
+    "show-session:Show properties of one or more sessions"
+    "activate:Activate a session"
+    "lock-session:Screen lock one or more sessions"
+    "unlock-session:Screen unlock one or more sessions"
+    "lock-sessions:Screen lock all current sessions"
+    "unlock-sessions:Screen unlock all current sessions"
+    "terminate-session:Terminate one or more sessions"
+    "kill-session:Send signal to processes of a session"
+    "list-users:List users"
+    "user-status:Show user status"
+    "show-user:Show properties of one or more users"
+    "enable-linger:Enable linger state of one or more users"
+    "disable-linger:Disable linger state of one or more users"
+    "terminate-user:Terminate all sessions of one or more users"
+    "kill-user:Send signal to processes of a user"
+    "list-seats:List seats"
+    "seat-status:Show seat status"
+    "show-seat:Show properties of one or more seats"
+    "attach:Attach one or more devices to a seat"
+    "flush-devices:Flush all device associations"
+    "terminate-seat:Terminate all sessions on one or more seats"
+  )
+
+  if (( CURRENT == 1 )); then
+    _describe -t commands 'loginctl command' _loginctl_cmds || compadd "$@"
+  else
+    local curcontext="$curcontext" _ignore
+
+    cmd="${${_loginctl_cmds[(r)$words[1]:*]%%:*}}"
+
+    if (( $#cmd )); then
+      curcontext="${curcontext%:*:*}:loginctl-${cmd}:"
+
+      _call_function ret _loginctl_$cmd || _message 'no more arguments'
+    else
+      _message "unknown loginctl command: $words[1]"
+    fi
+    return ret
+  fi
+}
+
+
+_arguments -s \
+    {-h,--help}'[Show help]' \
+    '--version[Show package version]' \
+    \*{-p+,--property=}'[Show only properties by this name]:unit property' \
+    {-a,--all}'[Show all properties, including empty ones]' \
+    '--kill-who=[Who to send signal to]:killwho:(main control all)' \
+    {-s+,--signal=}'[Which signal to send]:signal:_signals' \
+    {-H+,--host=}'[Operate on remote host]:userathost:_sd_hosts_or_user_at_host' \
+    {-M+,--machine=}'[Operate on local container]:machine:_sd_machines' \
+    {-l,--full}'[Do not ellipsize output]' \
+    '--no-pager[Do not pipe output into a pager]' \
+    '--no-legend[Do not show the headers and footers]' \
+    '--no-ask-password[Do not ask for system passwords]' \
+    {-n+,--lines=}'[Number of journal entries to show]' \
+    {-o+,--output=}'[Change journal output mode]:output modes:_sd_outputmodes' \
+    '*::loginctl command:_loginctl_command'
diff --git a/src/grp-login/systemd-inhibit/systemd-inhibit.completion.zsh b/src/grp-login/systemd-inhibit/systemd-inhibit.completion.zsh
new file mode 100644
index 0000000000..1b3247b2cd
--- /dev/null
+++ b/src/grp-login/systemd-inhibit/systemd-inhibit.completion.zsh
@@ -0,0 +1,33 @@
+#compdef systemd-inhibit
+
+_systemd_inhibit_command(){
+    if (( CURRENT == 1 )); then
+        compset -q
+        _normal
+    else
+        local n=${words[(b:2:i)[^-]*]}
+        if (( n <= CURRENT )); then
+            compset -n $n
+            _alternative \
+                'files:file:_files' \
+                'commands:command:_normal' && return 0
+        fi
+        _default
+    fi
+}
+
+_inhibit_what() {
+    local _inhibit
+    _inhibit=(shutdown sleep idle handle-power-key handle-suspend-key handle-hibernate-key handle-lid-switch)
+    _values -s : "${_inhibit[@]}"
+}
+
+_arguments \
+    {-h,--help}'[Show this help]' \
+    '--version[Show package version]' \
+    '--what=[Operations to inhibit]:options:_inhibit_what' \
+    '--who=[A descriptive string who is inhibiting]:who is inhibiting:' \
+    '--why=[A descriptive string why is being inhibited]:reason for the lock:' \
+    '--mode=[One of block or delay]:lock mode:( block delay )' \
+    '--list[List active inhibitors]' \
+    '*:commands:_systemd_inhibit_command'
-- 
cgit v1.2.3-54-g00ecf