1 files changed, 39 insertions, 0 deletions
diff --git a/community/wmii/PKGBUILD b/community/wmii/PKGBUILD
new file mode 100644
index 000000000..84407f57c
--- /dev/null
+++ b/community/wmii/PKGBUILD
@@ -0,0 +1,39 @@
+# $Id: PKGBUILD 65389 2012-02-21 02:31:44Z spupykin $
+# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
+# Contributor: Jeffrey 'jf' Lim <jfs.world@gmail.com>
+
+pkgname=wmii
+pkgver=3.9.2
+pkgrel=3
+pkgdesc="A small, dynamic window manager for X11"
+arch=('i686' 'x86_64')
+license=('MIT')
+url="http://wmii.suckless.org/"
+depends=('libxft' 'libxrandr' 'libxinerama' 'dash')
+options=('!makeflags')
+source=(http://dl.suckless.org/${pkgname}/${pkgname}+ixp-${pkgver}.tbz
+	'fix-freetype-include.patch')
+md5sums=('3d480502b7b1e2a405d941df67f16bcf'
+         '97febd4a1df80aa4afbd126de1f36496')
+
+build() {
+  cd ${srcdir}/${pkgname}+ixp-${pkgver}
+
+  patch -Np1 -i ${srcdir}/fix-freetype-include.patch
+
+  sed -i 's|PREFIX = /usr/local|PREFIX = /usr|' config.mk
+  sed -i 's|ETC = $(PREFIX)/etc|ETC = /etc|' config.mk
+  sed -i 's# !=#!=#' mk/hdr.mk
+  sed -i 's#env python#env python2#' alternative_wmiircs/python/wmiirc
+  echo 'LIBS+=-lXrender -lX11' >>config.mk
+
+  export MAKEFLAGS="-j1"
+  make
+}
+
+package() {
+  cd ${srcdir}/${pkgname}+ixp-${pkgver}
+  make DESTDIR=${pkgdir} install
+  install -Dm644 debian/file/wmii.desktop ${pkgdir}/usr/share/xsessions/${pkgname}.desktop
+  install -Dm644 LICENSE $pkgdir/usr/share/licenses/${pkgname}/LICENSE
+}