3 files changed, 85 insertions, 0 deletions
diff --git a/testing/ardour/PKGBUILD b/testing/ardour/PKGBUILD
new file mode 100644
index 000000000..cee3fc185
--- /dev/null
+++ b/testing/ardour/PKGBUILD
@@ -0,0 +1,50 @@
+# $Id: PKGBUILD 110738 2011-02-21 22:15:44Z schiv $
+# Maintainer: tobias <tobias@archlinux.org>
+# Maintainer: Ray Rashif <schiv@archlinux.org>
+# Contributor: Giovanni Scafora <giovanni@archlinux.org>
+
+# ardour, liblrdf and raptor are heavily dependent on each other. Updating of
+# one package mostly will require an update of all the other packages. I vote
+# for fixed dependencies speaking in terms of versions
+
+pkgname=ardour
+pkgver=2.8.11
+pkgrel=3
+pkgdesc="A multichannel hard disk recorder and digital audio workstation"
+arch=('i686' 'x86_64')
+url="http://ardour.org"
+license=('GPL')
+depends=('liblrdf>=0.4.0-7' 'liblo' 'aubio' 'libusb-compat'
+         'slv2>=0.6.6-3' 'rubberband' 'libgnomecanvas')
+makedepends=('scons' 'boost' 'pkg-config')
+changelog=${pkgname}.changelog
+source=(ftp://ftp.archlinux.org/other/ardour/${pkgname}-${pkgver}.tar.bz2
+        ${pkgname}.desktop)
+md5sums=('f451a8d0abc133a1700c3932e07a5612'
+         '8aeaf433ebf781733db48e5a16b0c4da')
+
+build() {
+  cd "${srcdir}/${pkgname}-${pkgver}"
+  sed -i '/-O3/d' SConstruct
+
+  scons ${MAKEFLAGS} ARCH="${CFLAGS}" \
+                     PREFIX="/usr" \
+                     DIST_LIBDIR="lib" \
+                     FREEDESKTOP=0 \
+                     FREESOUND=1 \
+                     DESTDIR="${pkgdir}"
+}
+
+package() {
+  cd "${srcdir}/${pkgname}-${pkgver}"
+
+  scons PREFIX="/usr" \
+        FREEDESKTOP=0 \
+        FREESOUND=1 \
+        DESTDIR="${pkgdir}" install
+
+  # install some freedesktop.org compatibility
+  install -Dm644 "${srcdir}/${pkgname}.desktop" "${pkgdir}/usr/share/applications/${pkgname}.desktop"
+}
+
+# vim:set ts=2 sw=2 et:
diff --git a/testing/ardour/ardour.changelog b/testing/ardour/ardour.changelog
new file mode 100644
index 000000000..ee9cf00bf
--- /dev/null
+++ b/testing/ardour/ardour.changelog
@@ -0,0 +1,26 @@
+22 Feb 2011 (GMT+8) Ray Rashif <schiv@archlinux.org>
+
+	* 2.8.11-2 :
+	raptor rebuild	
+
+9 Aug 2010 (GMT+8) Ray Rashif <schiv@archlinux.org>
+
+	* 2.8.11-1 :
+	Testing build.
+	Removed libgnomecanvasmm depend (ardour internal).
+	Removed soundtouch makedepend (ardour internal, unneded).
+	Added new depends
+		- slv2 ("LV2" plug-ins support)
+		- rubberband (can "do more" than soundtouch)
+		- libgnomecanvas
+	Not using SYSLIBS because upstream does not support it.
+	Namcap warnings can be ignored; they're ardour internals.
+
+	* PKGBUILD :
+	Minor cosmetic ammendments.
+
+	* ardour.changelog :
+	Added this changelog.
+
+	* ardour.install :
+	Removed install scriptlet; old and deprecated information.
diff --git a/testing/ardour/ardour.desktop b/testing/ardour/ardour.desktop
new file mode 100644
index 000000000..b50f6c952
--- /dev/null
+++ b/testing/ardour/ardour.desktop
@@ -0,0 +1,9 @@
+[Desktop Entry]
+Name=Ardour
+Comment=Multitrack hard disk recorder
+Exec=ardour2
+Icon=/usr/share/ardour2/icons/ardour_icon_48px.png
+Terminal=false
+Type=Application
+X-MultipleArgs=false
+Categories=GTK;Audio;AudioVideoEditing;AudioVideo;Video;