1 files changed, 31 insertions, 0 deletions
diff --git a/testing/bzr/PKGBUILD b/testing/bzr/PKGBUILD
new file mode 100644
index 000000000..58b6598b4
--- /dev/null
+++ b/testing/bzr/PKGBUILD
@@ -0,0 +1,31 @@
+# $Id: PKGBUILD 136469 2011-08-29 21:41:53Z eric $
+# Maintainer :
+# Contributor: Hugo Doria <hugo@archlinux.org>
+
+pkgname=bzr
+pkgver=2.4.0
+pkgrel=1
+pkgdesc="A decentralized revision control system (bazaar)"
+arch=('i686' 'x86_64')
+url="http://bazaar.canonical.com/en/"
+license=('GPL')
+depends=('python2')
+optdepends=('python-paramiko: for sftp support')
+source=("http://launchpad.net/${pkgname}/${pkgver%.*}/${pkgver}/+download/${pkgname}-${pkgver}.tar.gz")
+md5sums=('087c65e4b79f454b9e733c21607bdd56')
+
+build() {
+  cd "${srcdir}/${pkgname}-${pkgver}"
+  sed -i 's|man/man1|share/man/man1|' setup.py
+  sed -i 's|/usr/bin/env python|/usr/bin/env python2|' \
+    bzrlib/{plugins/bash_completion/bashcomp.py,tests/ssl_certs/create_ssls.py,patiencediff.py,_patiencediff_py.py}
+  python2 setup.py build
+}
+
+package() {
+  cd "${srcdir}/${pkgname}-${pkgver}"
+  python2 setup.py install --prefix=/usr --root="${pkgdir}" --optimize=1
+
+  # bash-completion
+  install -D -m644 contrib/bash/bzr "${pkgdir}/etc/bash_completion.d/bzr"
+}