From ffd2d3e0b0ac6b10b12ddc1e8747a0fb8b847667 Mon Sep 17 00:00:00 2001
From: root <root@rshg054.dnsready.net>
Date: Mon, 13 Aug 2012 00:02:34 +0000
Subject: Mon Aug 13 00:02:34 UTC 2012

---
 community-staging/avr-gcc/PKGBUILD | 72 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 72 insertions(+)
 create mode 100644 community-staging/avr-gcc/PKGBUILD

(limited to 'community-staging/avr-gcc')

diff --git a/community-staging/avr-gcc/PKGBUILD b/community-staging/avr-gcc/PKGBUILD
new file mode 100644
index 000000000..59f9bb536
--- /dev/null
+++ b/community-staging/avr-gcc/PKGBUILD
@@ -0,0 +1,72 @@
+# $Id: PKGBUILD 75007 2012-08-11 13:56:52Z schuay $
+# Maintainer: schuay <jakob.gruber@gmail.com>
+# Contributor: Brad Fanella <bradfanella@archlinux.us>
+# Contributor: Corrado Primier <bardo@aur.archlinux.org>
+# Contributor: danst0 <danst0@west.de>
+
+# Build order: avr-binutils -> avr-gcc -> avr-libc
+
+pkgname=avr-gcc
+_pkgname=gcc
+pkgver=4.7.1
+pkgrel=2
+pkgdesc="The GNU AVR Compiler Collection"
+arch=('i686' 'x86_64')
+license=('GPL' 'LGPL' 'custom')
+url="http://gcc.gnu.org/"
+depends=('avr-binutils>=2.22-3' 'cloog' 'ppl' 'gcc-libs>=4.7.0' 'libmpc')
+provides=("gcc-avr=$pkgver")
+replaces=('gcc-avr')
+options=('!libtool' '!emptydirs' '!libtool' '!strip')
+source=(http://ftp.gnu.org/gnu/gcc/${_pkgname}-${pkgver}/gcc-${pkgver}.tar.bz2)
+
+_basedir=${srcdir}/${_pkgname}-${pkgver}
+
+build() {
+    # default CFLAGS lead to issues later on when configure 
+    # calls avr-gcc with -march set.
+    export CFLAGS="-O2 -pipe"
+    export CXXFLAGS="-O2 -pipe"
+
+    cd ${_basedir} 
+
+    # Do not install libiberty
+    sed -i 's/install_to_$(INSTALL_DEST) //' libiberty/Makefile.in
+
+    echo ${pkgver} > gcc/BASE-VER
+
+    cd ${srcdir}
+    mkdir gcc-build && cd gcc-build
+
+    ${_basedir}/configure \
+                --prefix=/usr \
+                --libdir=/usr/lib \
+                --libexecdir=/usr/lib \
+                --mandir=/usr/share/man \
+                --infodir=/usr/share/info \
+                --enable-languages=c,c++ \
+                --disable-libssp \
+                --disable-nls \
+                --target=avr \
+                --with-as=/usr/bin/avr-as \
+                --with-ld=/usr/bin/avr-ld \
+                --with-gnu-as \
+                --with-gnu-ld
+
+    make
+}
+
+package() {
+    cd ${srcdir}/gcc-build
+
+    make -j1 DESTDIR=${pkgdir} install
+
+      # Install Runtime Library Exception
+    install -Dm644 ${_basedir}/COPYING.RUNTIME \
+        ${pkgdir}/usr/share/licenses/${pkgname}/RUNTIME.LIBRARY.EXCEPTION
+
+    rm -rf ${pkgdir}/usr/share/man/man7
+    rm -rf ${pkgdir}/usr/share/info
+}
+
+md5sums=('933e6f15f51c031060af64a9e14149ff')
-- 
cgit v1.2.3-54-g00ecf