From 01b47af6474ac094ec199c7d75208874f8842d87 Mon Sep 17 00:00:00 2001
From: root <root@rshg047.dnsready.net>
Date: Tue, 10 May 2011 22:33:36 +0000
Subject: Tue May 10 22:33:36 UTC 2011

---
 extra/java-commons-daemon/PKGBUILD | 49 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)
 create mode 100644 extra/java-commons-daemon/PKGBUILD

(limited to 'extra/java-commons-daemon')

diff --git a/extra/java-commons-daemon/PKGBUILD b/extra/java-commons-daemon/PKGBUILD
new file mode 100644
index 000000000..91d32fd90
--- /dev/null
+++ b/extra/java-commons-daemon/PKGBUILD
@@ -0,0 +1,49 @@
+# Maintainer: Guillaume ALAUX <guillaume@archlinux.org>
+pkgname=('java-commons-daemon' 'java-jsvc')
+pkgbase=java-commons-daemon
+pkgver=1.0.5
+pkgrel=1
+arch=('i686' 'x86_64')
+url="http://commons.apache.org/daemon/"
+license=('APACHE')
+_libname=commons-daemon
+source=(http://archive.apache.org/dist/commons/daemon/source/${_libname}-${pkgver}-src.tar.gz)
+md5sums=('2fe0a35d4a9c0338ecd45dad20f33662')
+makedepends=('apache-ant' 'docbook2x' 'docbook-xsl')
+
+
+build() {
+  # commons-daemon.jar
+  cd "${srcdir}/${_libname}-${pkgver}-src"
+  ant
+
+  # jsvc
+  cd "${srcdir}/${_libname}-${pkgver}-src/src/native/unix"
+  ./configure
+  make
+  docbook2man man/jsvc.1.xml
+}
+
+package_java-commons-daemon() {
+  pkgdesc="Set of Apache libraries for making Java applications run on UNIX more easily"
+  depends=('java-runtime')
+
+  cd "${srcdir}/${_libname}-${pkgver}-src"
+
+  install -Dm755 dist/${_libname}-${pkgver}.jar \
+                 ${pkgdir}/usr/share/java/${_libname}-${pkgver}.jar
+  ln -s ${_libname}-${pkgver}.jar \
+        ${pkgdir}/usr/share/java/${_libname}.jar
+}
+
+package_java-jsvc() {
+  pkgdesc="Apache application for making Java applications run on UNIX more easily"
+  depends=("java-${_libname}" 'libcap')
+
+  # jsvc
+  cd "${srcdir}/${_libname}-${pkgver}-src/src/native/unix"
+
+  install -Dm755 jsvc ${pkgdir}/usr/bin/jsvc
+  install -Dm644 JSVC.1 ${pkgdir}/usr/share/man/man1/JSVC.1
+}
+
-- 
cgit v1.2.3-54-g00ecf