From 5dd7ed82e788ebad2e920e0f2db7468cc6547cfe Mon Sep 17 00:00:00 2001
From: root <root@rshg054.dnsready.net>
Date: Sat, 29 Dec 2012 02:13:48 -0800
Subject: Sat Dec 29 02:10:20 PST 2012

---
 extra/kdelibs/PKGBUILD | 65 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 65 insertions(+)
 create mode 100644 extra/kdelibs/PKGBUILD

(limited to 'extra/kdelibs/PKGBUILD')

diff --git a/extra/kdelibs/PKGBUILD b/extra/kdelibs/PKGBUILD
new file mode 100644
index 000000000..4d7f51fa5
--- /dev/null
+++ b/extra/kdelibs/PKGBUILD
@@ -0,0 +1,65 @@
+# $Id: PKGBUILD 173891 2012-12-27 10:11:14Z andrea $
+# Maintainer: Andrea Scarpino <andrea@archlinux.org
+# Contributor: Pierre Schmitz <pierre@archlinux.de>
+
+pkgname=kdelibs
+pkgver=4.9.4
+pkgrel=4
+pkgdesc="KDE Core Libraries"
+arch=('i686' 'x86_64')
+url='https://projects.kde.org/projects/kde/kdelibs'
+license=('GPL' 'LGPL' 'FDL')
+depends=('strigi' 'attica' 'libxss' 'soprano' 'krb5' 'grantlee'
+        'shared-desktop-ontologies' 'qca' 'libdbusmenu-qt' 'polkit-qt'
+        'shared-mime-info' 'enchant' 'giflib' 'jasper' 'openexr'
+        'docbook-xsl' 'upower' 'udisks' 'libxcursor' 'phonon' 'qtwebkit'
+        'media-player-info' 'libxtst' 'libutempter')
+makedepends=('cmake' 'automoc4' 'avahi' 'libgl' 'hspell' 'mesa')
+install=${pkgname}.install
+source=("http://download.kde.org/stable/${pkgver}/src/${pkgname}-${pkgver}.tar.xz"
+        'kde-applications-menu.patch' 'archlinux-menu.patch'
+        '0001-Revert-Also-check-parent-mimetypes-in-protocolForArc.patch'
+        'fix-crash-on-open-with.patch')
+sha1sums=('b2fe70261207a96a26b5d8789379f134e3e070be'
+          '86ee8c8660f19de8141ac99cd6943964d97a1ed7'
+          '63a850ab4196b9d06934f2b4a13acd9f7739bc67'
+          'f5d203932f67ab6d87c794e9cb78a3b1a22ef747'
+          '8faa5984ba37e9c6da04bc64f1fe21cd24f1cf07')
+
+build() {
+       cd "${srcdir}"/${pkgname}-${pkgver}
+
+       # avoid file conflict with gnome-menus
+       patch -p1 -i "${srcdir}"/kde-applications-menu.patch
+       # add Archlinux menu entry
+       patch -p1 -i "${srcdir}"/archlinux-menu.patch
+
+       # Fixed upstream
+       patch -p1 -i "${srcdir}"/0001-Revert-Also-check-parent-mimetypes-in-protocolForArc.patch
+       patch -p1 -i "${srcdir}"/fix-crash-on-open-with.patch
+
+       cd "${srcdir}"
+       mkdir build
+       cd build
+       cmake ../${pkgname}-${pkgver} \
+               -DCMAKE_BUILD_TYPE=Release \
+               -DCMAKE_SKIP_RPATH=ON \
+               -DKDE_DISTRIBUTION_TEXT='Arch Linux' \
+               -DCMAKE_INSTALL_PREFIX=/usr \
+               -DSYSCONF_INSTALL_DIR=/etc \
+               -DHTML_INSTALL_DIR=/usr/share/doc/kde/html \
+               -DKDE_DEFAULT_HOME='.kde4' \
+               -DWITH_FAM=OFF \
+               -DWITH_HUpnp=OFF
+       make
+}
+
+package() {
+       cd "${srcdir}"/build
+       make DESTDIR="${pkgdir}" install
+
+       # cert bundle seems to be hardcoded
+       # link it to the one from ca-certificates
+       rm -f "${pkgdir}"/usr/share/apps/kssl/ca-bundle.crt
+       ln -sf /etc/ssl/certs/ca-certificates.crt "${pkgdir}"/usr/share/apps/kssl/ca-bundle.crt
+}
-- 
cgit v1.2.3-54-g00ecf