From 956ae4eb53422c92f78d86d5511f25fbf6fa6497 Mon Sep 17 00:00:00 2001
From: root <root@rshg047.dnsready.net>
Date: Thu, 26 May 2011 22:47:02 +0000
Subject: Thu May 26 22:47:02 UTC 2011

---
 kde-unstable/kdewebdev/PKGBUILD | 67 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 67 insertions(+)
 create mode 100644 kde-unstable/kdewebdev/PKGBUILD

(limited to 'kde-unstable/kdewebdev/PKGBUILD')

diff --git a/kde-unstable/kdewebdev/PKGBUILD b/kde-unstable/kdewebdev/PKGBUILD
new file mode 100644
index 000000000..d70b92ee0
--- /dev/null
+++ b/kde-unstable/kdewebdev/PKGBUILD
@@ -0,0 +1,67 @@
+# $Id: PKGBUILD 124779 2011-05-24 12:04:03Z andrea $
+# Maintainer: Pierre Schmitz <pierre@archlinux.de>
+
+pkgbase=kdewebdev
+pkgname=('kdewebdev-kfilereplace'
+         'kdewebdev-kimagemapeditor'
+         'kdewebdev-klinkstatus'
+         'kdewebdev-kommander')
+pkgver=4.6.80
+pkgrel=1
+arch=('i686' 'x86_64')
+url='http://www.kde.org'
+license=('GPL' 'LGPL' 'FDL')
+groups=('kde' 'kdewebdev')
+makedepends=('pkgconfig' 'cmake' 'automoc4' 'ruby' 'tidyhtml' 'kdepim-runtime'
+	'boost')
+source=("http://download.kde.org/unstable/${pkgver}/src/${pkgbase}-${pkgver}.tar.bz2")
+sha1sums=('d5e35391eb64265f66d81c5bdd8d95abf11d474a')
+
+build() {
+	cd $srcdir
+	mkdir build
+	cd build
+	cmake ../${pkgbase}-${pkgver} \
+		-DCMAKE_BUILD_TYPE=Release \
+		-DCMAKE_SKIP_RPATH=ON \
+		-DCMAKE_INSTALL_PREFIX=/usr
+	make
+}
+
+package_kdewebdev-kfilereplace() {
+	pkgdesc='Search & Replace Tool'
+	depends=('kdebase-runtime')
+	url="http://kde.org/applications/utilities/kfilereplace/"
+	install='kdewebdev.install'
+	cd $srcdir/build/kfilereplace
+	make DESTDIR=$pkgdir install
+	cd $srcdir/build/doc/kfilereplace
+	make DESTDIR=$pkgdir install
+}
+
+package_kdewebdev-kimagemapeditor() {
+	pkgdesc='HTML Image Map Editor'
+	depends=('kdebase-runtime')
+	install='kdewebdev.install'
+	cd $srcdir/build/kimagemapeditor
+	make DESTDIR=$pkgdir install
+	cd $srcdir/build/doc/kimagemapeditor
+	make DESTDIR=$pkgdir install
+}
+
+package_kdewebdev-klinkstatus() {
+	pkgdesc='Link Checker'
+	depends=('kdepim-runtime' 'tidyhtml')
+	install='kdewebdev.install'
+	cd $srcdir/build/klinkstatus
+	make DESTDIR=$pkgdir install
+	cd $srcdir/build/doc/klinkstatus
+	make DESTDIR=$pkgdir install
+}
+
+package_kdewebdev-kommander() {
+	pkgdesc='Executor for Kommander dialogs'
+	depends=('kdebase-runtime')
+	cd $srcdir/build/kommander
+	make DESTDIR=$pkgdir install
+}
-- 
cgit v1.2.3-54-g00ecf