From 52442b30a60f3a0dc7bc0eb214d123d001987c83 Mon Sep 17 00:00:00 2001
From: root <root@rshg054.dnsready.net>
Date: Wed, 7 Sep 2011 15:14:25 +0000
Subject: Wed Sep  7 15:14:25 UTC 2011

---
 staging/kdeadmin/PKGBUILD          | 77 ++++++++++++++++++++++++++++++++++++++
 staging/kdeadmin/kdeadmin.install  | 11 ++++++
 staging/kdeadmin/syslog-path.patch | 11 ++++++
 3 files changed, 99 insertions(+)
 create mode 100644 staging/kdeadmin/PKGBUILD
 create mode 100644 staging/kdeadmin/kdeadmin.install
 create mode 100644 staging/kdeadmin/syslog-path.patch

(limited to 'staging/kdeadmin')

diff --git a/staging/kdeadmin/PKGBUILD b/staging/kdeadmin/PKGBUILD
new file mode 100644
index 000000000..546057d0d
--- /dev/null
+++ b/staging/kdeadmin/PKGBUILD
@@ -0,0 +1,77 @@
+# $Id: PKGBUILD 137252 2011-09-06 21:34:45Z andrea $
+# Maintainer: Andrea Scarpino <andrea@archlinux.org>
+# Contributor: Pierre Schmitz <pierre@archlinux.de>
+
+pkgbase=kdeadmin
+pkgname=('kdeadmin-kcron'
+         'kdeadmin-ksystemlog'
+         'kdeadmin-kuser'
+         'kdeadmin-system-config-printer-kde')
+pkgver=4.7.1
+pkgrel=1
+arch=('i686' 'x86_64')
+url='http://www.kde.org'
+license=('GPL' 'LGPL' 'FDL')
+groups=('kde' 'kdeadmin')
+makedepends=('pkgconfig' 'cmake' 'automoc4' 'kdebindings-python'
+	         'system-config-printer-common')
+source=("http://download.kde.org/stable/${pkgver}/src/${pkgbase}-${pkgver}.tar.bz2"
+        'syslog-path.patch')
+sha1sums=('3d1b1be2003fe20c5c3faee63ba31c65621d53b7'
+          '20095ce6e0f3e5b6800a7c6e52de6fddba62c031')
+
+build() {
+	cd ${srcdir}/${pkgbase}-${pkgver}
+	patch -p1 -i ${srcdir}/syslog-path.patch
+
+	cd ${srcdir}
+	mkdir build
+	cd build
+	cmake ../${pkgbase}-${pkgver} \
+		-DCMAKE_BUILD_TYPE=Release \
+		-DCMAKE_SKIP_RPATH=ON \
+		-DCMAKE_INSTALL_PREFIX=/usr \
+		-DBUILD_strigi-analyzer=OFF
+	make
+}
+
+package_kdeadmin-kcron() {
+	pkgdesc='Configure and schedule tasks'
+	depends=('kdelibs')
+	cd $srcdir/build/kcron
+	make DESTDIR=$pkgdir install
+	cd $srcdir/build/doc/kcron
+	make DESTDIR=$pkgdir install
+}
+
+package_kdeadmin-ksystemlog() {
+	pkgdesc='System log viewer tool'
+	depends=('kdebase-runtime')
+	url="http://kde.org/applications/system/ksystemlog/"
+	cd $srcdir/build/ksystemlog
+	make DESTDIR=$pkgdir install
+	cd $srcdir/build/doc/ksystemlog
+	make DESTDIR=$pkgdir install
+}
+
+package_kdeadmin-kuser() {
+	pkgdesc='User Manager'
+	depends=('kdepim-runtime')
+	url="http://kde.org/applications/system/kuser/"
+	install='kdeadmin.install'
+	cd $srcdir/build/kuser
+	make DESTDIR=$pkgdir install
+	cd $srcdir/build/doc/kuser
+	make DESTDIR=$pkgdir install
+}
+
+package_kdeadmin-system-config-printer-kde() {
+	pkgdesc='Configure local and remote Printers'
+	depends=('kdebindings-python' 'system-config-printer-common' 'python2-pyqt')
+	url="http://kde.org/applications/system/printerapplet/"
+	cd $srcdir/build/system-config-printer-kde
+	make DESTDIR=$pkgdir install
+
+    # Use the python2 executable
+    find ${pkgdir} -name '*.py' | xargs sed -i 's|#!/usr/bin/env python|#!/usr/bin/env python2|'
+}
diff --git a/staging/kdeadmin/kdeadmin.install b/staging/kdeadmin/kdeadmin.install
new file mode 100644
index 000000000..e70c054ec
--- /dev/null
+++ b/staging/kdeadmin/kdeadmin.install
@@ -0,0 +1,11 @@
+post_install() {
+	xdg-icon-resource forceupdate --theme hicolor &> /dev/null
+}
+
+post_upgrade() {
+	post_install
+}
+
+post_remove() {
+	post_install
+}
diff --git a/staging/kdeadmin/syslog-path.patch b/staging/kdeadmin/syslog-path.patch
new file mode 100644
index 000000000..8a9142bf6
--- /dev/null
+++ b/staging/kdeadmin/syslog-path.patch
@@ -0,0 +1,11 @@
+--- kdeadmin-4.6.0/ksystemlog/src/modes/system/systemConfiguration.h~	2011-01-27 14:24:29.840000005 +0100
++++ kdeadmin-4.6.0/ksystemlog/src/modes/system/systemConfiguration.h	2011-01-27 14:24:53.803333335 +0100
+@@ -39,7 +39,7 @@
+ 		SystemConfiguration() :
+ 			GenericLogModeConfiguration(
+ 					QLatin1String( SYSTEM_LOG_MODE_ID ),
+-					QStringList() << QLatin1String( "/var/log/syslog" ),
++					QStringList() << QLatin1String( "/var/log/messages.log" ),
+ 					QList<int>() << INFORMATION_LOG_LEVEL_ID
+ 			) {
+ 
-- 
cgit v1.2.3-54-g00ecf