From bd65dc7107bfdd881c3b5451d0300824cf435428 Mon Sep 17 00:00:00 2001
From: Parabola <dev@list.parabolagnulinux.org>
Date: Thu, 7 Apr 2011 03:09:25 +0000
Subject: Thu Apr  7 03:09:43 UTC 2011

---
 staging/kdewebdev/PKGBUILD          | 67 +++++++++++++++++++++++++++++++++++++
 staging/kdewebdev/kdewebdev.install | 11 ++++++
 2 files changed, 78 insertions(+)
 create mode 100644 staging/kdewebdev/PKGBUILD
 create mode 100644 staging/kdewebdev/kdewebdev.install

(limited to 'staging/kdewebdev')

diff --git a/staging/kdewebdev/PKGBUILD b/staging/kdewebdev/PKGBUILD
new file mode 100644
index 000000000..e0a90a5c9
--- /dev/null
+++ b/staging/kdewebdev/PKGBUILD
@@ -0,0 +1,67 @@
+# $Id: PKGBUILD 118080 2011-04-05 10:08:44Z andrea $
+# Maintainer: Pierre Schmitz <pierre@archlinux.de>
+
+pkgbase=kdewebdev
+pkgname=('kdewebdev-kfilereplace'
+         'kdewebdev-kimagemapeditor'
+         'kdewebdev-klinkstatus'
+         'kdewebdev-kommander')
+pkgver=4.6.2
+pkgrel=1
+arch=('i686' 'x86_64')
+url='http://www.kde.org'
+license=('GPL' 'LGPL' 'FDL')
+groups=('kde' 'kdewebdev')
+makedepends=('pkgconfig' 'cmake' 'automoc4' 'ruby' 'tidyhtml' 'kdepim-runtime'
+	'docbook-xsl' 'boost')
+source=("http://download.kde.org/stable/${pkgver}/src/${pkgbase}-${pkgver}.tar.bz2")
+sha1sums=('80f709845fb871919fbb2c293d1cc8f40160509b')
+
+build() {
+	cd $srcdir
+	mkdir build
+	cd build
+	cmake ../${pkgbase}-${pkgver} \
+		-DCMAKE_BUILD_TYPE=Release \
+		-DCMAKE_SKIP_RPATH=ON \
+		-DCMAKE_INSTALL_PREFIX=/usr
+	make
+}
+
+package_kdewebdev-kfilereplace() {
+	pkgdesc='Search & Replace Tool'
+	depends=('kdebase-runtime')
+	url="http://kde.org/applications/utilities/kfilereplace/"
+	install='kdewebdev.install'
+	cd $srcdir/build/kfilereplace
+	make DESTDIR=$pkgdir install
+	cd $srcdir/build/doc/kfilereplace
+	make DESTDIR=$pkgdir install
+}
+
+package_kdewebdev-kimagemapeditor() {
+	pkgdesc='HTML Image Map Editor'
+	depends=('kdebase-runtime')
+	install='kdewebdev.install'
+	cd $srcdir/build/kimagemapeditor
+	make DESTDIR=$pkgdir install
+	cd $srcdir/build/doc/kimagemapeditor
+	make DESTDIR=$pkgdir install
+}
+
+package_kdewebdev-klinkstatus() {
+	pkgdesc='Link Checker'
+	depends=('kdepim-runtime' 'tidyhtml')
+	install='kdewebdev.install'
+	cd $srcdir/build/klinkstatus
+	make DESTDIR=$pkgdir install
+	cd $srcdir/build/doc/klinkstatus
+	make DESTDIR=$pkgdir install
+}
+
+package_kdewebdev-kommander() {
+	pkgdesc='Executor for Kommander dialogs'
+	depends=('kdebase-runtime')
+	cd $srcdir/build/kommander
+	make DESTDIR=$pkgdir install
+}
diff --git a/staging/kdewebdev/kdewebdev.install b/staging/kdewebdev/kdewebdev.install
new file mode 100644
index 000000000..e70c054ec
--- /dev/null
+++ b/staging/kdewebdev/kdewebdev.install
@@ -0,0 +1,11 @@
+post_install() {
+	xdg-icon-resource forceupdate --theme hicolor &> /dev/null
+}
+
+post_upgrade() {
+	post_install
+}
+
+post_remove() {
+	post_install
+}
-- 
cgit v1.2.3-54-g00ecf