From e7b9c9697e6a50c3b9e78941fa95ba11c716d238 Mon Sep 17 00:00:00 2001
From: root <root@rshg047.dnsready.net>
Date: Wed, 1 Jun 2011 22:46:45 +0000
Subject: Wed Jun  1 22:46:45 UTC 2011

---
 testing/claws-mail-extra-plugins/PKGBUILD | 67 +++++++++++++++++++++++++++++++
 1 file changed, 67 insertions(+)
 create mode 100644 testing/claws-mail-extra-plugins/PKGBUILD

(limited to 'testing/claws-mail-extra-plugins/PKGBUILD')

diff --git a/testing/claws-mail-extra-plugins/PKGBUILD b/testing/claws-mail-extra-plugins/PKGBUILD
new file mode 100644
index 000000000..9d233d726
--- /dev/null
+++ b/testing/claws-mail-extra-plugins/PKGBUILD
@@ -0,0 +1,67 @@
+# $Id: PKGBUILD 125144 2011-05-25 19:01:27Z foutrelis $
+# Maintainer: Andreas Radke <andyrtr@archlinux.org>
+# Contributor: Mildred <mildred593 at online dot fr>
+
+pkgname=claws-mail-extra-plugins
+pkgver=3.7.9
+pkgrel=4
+pkgdesc="Extra plugins for claws-mail"
+url="http://www.claws-mail.org/plugins.php?branch=EXT"
+license=('GPL3')
+arch=('i686' 'x86_64')
+depends=('claws-mail>=3.7.8')
+makedepends=('make' 'bc' 'perl>=5.10.1-5' 'libgtkhtml>=2.11.1-2' 'libnotify>=0.7'
+             'libxml2>=2.7.6' 'curl>=7.19.7' 'libytnef>=1.5-2' 'libwebkit>=1.3.13'
+             'pygtk>=2.16.0' 'libsoup-gnome' 'libcanberra')
+optdepends=('libgtkhtml: for gtkhtml2_viewer plugin'
+            'perl: for perl plugin'
+            'libnotify: for notification plugin'
+            'libcanberra: for notification plugin'
+            'dbus-core: for notification plugin'
+            'libxml2: for gtkhtml2_viewer and rssyl plugins'
+            'curl: for gtkhtml2_viewer, vcalendar, rssyl and spamreport plugins'
+            'libarchive: for archive plugin'
+            'libytnef: for tnef_parse plugin'
+            'libwebkit: for the fancy webkit html plugin'
+            'libsoup-gnome: for the fancy webkit html plugin'
+            'python2: for python plugin')
+conflicts=('claws-gtkhtml2_viewer' 'claws-mail-acpinotifier-plugin'
+           'sylpheed-claws-gtkhtml2-plugin' 'sylpheed-claws-rssyl-plugin'
+           'sylpheed-claws-extra-plugins' 'claws-tnef-plugin'
+           'claws-webkit-plugin-svn' 'claws-mayflower-plugin-svn')
+replaces=('sylpheed-claws-extra-plugins')
+options=('!libtool' '!strip')
+source=(http://downloads.sourceforge.net/project/sylpheed-claws/extra%20plugins/$pkgver/claws-mail-extra-plugins-$pkgver.tar.bz2
+        claws-mail-notification-0.26-libnotify-0.7.patch)
+md5sums=('3d1ebc48f686ab10702380c776b5d5d0'
+         'a02be84594ebd28b18811ccc358509be')
+
+build() {
+  cd "$srcdir/claws-mail-extra-plugins-$pkgver"
+
+  # fix for python2
+  export PYTHON="/usr/bin/python2"
+
+  for dir in */; do
+    [[ $dir != geolocation_plugin-* ]] && (
+      cd $dir
+
+      [[ $dir == notification_plugin-* ]] &&
+        patch -Np2 -i "$srcdir/claws-mail-notification-0.26-libnotify-0.7.patch"
+
+      ./configure --prefix=/usr --disable-static
+      make
+    )
+  done
+}
+
+package() {
+  cd "$srcdir/claws-mail-extra-plugins-$pkgver"
+  for dir in */; do
+    [[ $dir != geolocation_plugin-* ]] && 
+      make -C $dir DESTDIR="$pkgdir" install
+  done
+
+  # fix fileconflict with libical, #11485
+  rm -f "$pkgdir/usr/include/ical.h"
+}
-- 
cgit v1.2.3-54-g00ecf