From 483f7de4ab6a706517279a24d2efc969f4a1996d Mon Sep 17 00:00:00 2001
From: root <root@rshg054.dnsready.net>
Date: Mon, 28 May 2012 17:43:57 +0000
Subject: Mon May 28 17:43:57 UTC 2012

---
 testing/claws-mail-extra-plugins/PKGBUILD | 66 +++++++++++++++++++++++++++++++
 1 file changed, 66 insertions(+)
 create mode 100644 testing/claws-mail-extra-plugins/PKGBUILD

(limited to 'testing/claws-mail-extra-plugins')

diff --git a/testing/claws-mail-extra-plugins/PKGBUILD b/testing/claws-mail-extra-plugins/PKGBUILD
new file mode 100644
index 000000000..187290ab2
--- /dev/null
+++ b/testing/claws-mail-extra-plugins/PKGBUILD
@@ -0,0 +1,66 @@
+# $Id: PKGBUILD 159823 2012-05-27 07:41:56Z bluewind $
+# Maintainer: Andreas Radke <andyrtr@archlinux.org>
+# Contributor: Mildred <mildred593 at online dot fr>
+
+pkgname=claws-mail-extra-plugins
+pkgver=3.8.0
+pkgrel=3
+pkgdesc="Extra plugins for claws-mail"
+url="http://www.claws-mail.org/plugins.php?branch=EXT"
+license=('GPL3')
+arch=('i686' 'x86_64')
+depends=('claws-mail>=3.8.0')
+makedepends=('make' 'bc' 'perl>=5.16.0' 'libgtkhtml>=2.11.1-2' 'libnotify>=0.7'
+             'libxml2>=2.7.6' 'curl>=7.19.7' 'libytnef>=1.5-2' 'libwebkit>=1.6.1'
+             'pygtk>=2.16.0' 'libsoup-gnome' 'libcanberra' 'libgdata')
+optdepends=('libgtkhtml: for gtkhtml2_viewer plugin'
+            'perl: for perl plugin'
+            'libnotify: for notification plugin'
+            'libcanberra: for notification plugin'
+            'dbus-core: for notification plugin'
+            'libxml2: for gtkhtml2_viewer and rssyl plugins'
+            'curl: for gtkhtml2_viewer, vcalendar, rssyl and spamreport plugins'
+            'libarchive: for archive plugin'
+            'libytnef: for tnef_parse plugin'
+            'libwebkit: for the fancy webkit html plugin'
+            'libsoup-gnome: for the fancy webkit html plugin'
+            'python2: for python plugin'
+	    'libgdata: for gdata plugin')
+conflicts=('claws-gtkhtml2_viewer' 'claws-mail-acpinotifier-plugin'
+           'sylpheed-claws-gtkhtml2-plugin' 'sylpheed-claws-rssyl-plugin'
+           'sylpheed-claws-extra-plugins' 'claws-tnef-plugin'
+           'claws-webkit-plugin-svn' 'claws-mayflower-plugin-svn')
+replaces=('sylpheed-claws-extra-plugins')
+options=('!libtool' '!strip')
+source=(http://downloads.sourceforge.net/project/sylpheed-claws/extra%20plugins/$pkgver/claws-mail-extra-plugins-$pkgver.tar.bz2)
+md5sums=('4776f6e0357a694f384349ac73b6da52')
+
+build() {
+  cd "$srcdir/claws-mail-extra-plugins-$pkgver"
+
+  # fix for python2
+  export PYTHON="/usr/bin/python2"
+
+  # fix gdata plugin build
+  sed -i -e "s:libgdata\ <\ 0.9.0:libgdata\ <\ 0.11.0:g" gdata_plugin-0.3/configure
+ 
+  for dir in */; do
+    [[ $dir != geolocation_plugin-* ]] && (
+      cd $dir
+
+      ./configure --prefix=/usr --disable-static
+      make
+    )
+  done
+}
+
+package() {
+  cd "$srcdir/claws-mail-extra-plugins-$pkgver"
+  for dir in */; do
+    [[ $dir != geolocation_plugin-* ]] && 
+      make -C $dir DESTDIR="$pkgdir" install
+  done
+
+  # fix fileconflict with libical, #11485
+  rm -f "$pkgdir/usr/include/ical.h"
+}
-- 
cgit v1.2.3-54-g00ecf