From 6ca29e0c62691c1f3120dda0f6b59dbb86cc9295 Mon Sep 17 00:00:00 2001
From: root <root@rshg047.dnsready.net>
Date: Mon, 18 Apr 2011 05:50:22 +0000
Subject: Mon Apr 18 05:50:22 UTC 2011

---
 testing/curl/PKGBUILD    | 52 ++++++++++++++++++++++++++++++++++++++++++++++++
 testing/curl/curlbuild.h |  9 +++++++++
 2 files changed, 61 insertions(+)
 create mode 100644 testing/curl/PKGBUILD
 create mode 100644 testing/curl/curlbuild.h

(limited to 'testing/curl')

diff --git a/testing/curl/PKGBUILD b/testing/curl/PKGBUILD
new file mode 100644
index 000000000..54287473b
--- /dev/null
+++ b/testing/curl/PKGBUILD
@@ -0,0 +1,52 @@
+# $Id: PKGBUILD 119987 2011-04-18 02:10:36Z angvp $
+# Maintainer: Angel Velasquez <angvp@archlinux.org>
+# Contributor: Eric Belanger <eric@archlinux.org>
+# Contributor: Lucien Immink <l.immink@student.fnt.hvu.nl>
+# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
+
+pkgname=curl
+pkgver=7.21.5
+pkgrel=1
+pkgdesc="An URL retrival utility and library"
+arch=('i686' 'x86_64')
+url="http://curl.haxx.se"
+license=('MIT')
+depends=('zlib' 'openssl' 'bash' 'ca-certificates')
+options=('!libtool')
+source=(http://curl.haxx.se/download/${pkgname}-${pkgver}.tar.bz2
+        curlbuild.h)
+md5sums=('dadd6353c9407161ddd62c0943718d59'
+         '751bd433ede935c8fae727377625a8ae')
+
+[[ $CARCH == "x86_64" ]] && _curlbuild=curlbuild-64.h
+[[ $CARCH == "i686" ]] && _curlbuild=curlbuild-32.h
+build() {
+    cd ${srcdir}/${pkgname}-${pkgver}
+
+    ./configure \
+        --with-random=/dev/urandom \
+        --prefix=/usr \
+        --mandir=/usr/share/man \
+        --disable-dependency-tracking \
+        --enable-ipv6 \
+        --disable-ldaps \
+        --disable-ldap \
+        --enable-manual \
+        --enable-versioned-symbols \
+        --with-ca-bundle=/etc/ssl/certs/ca-certificates.crt \
+        --without-libidn \
+        --enable-threaded-resolver
+    make
+}
+
+package() {
+    cd ${srcdir}/${pkgname}-${pkgver}
+
+    make DESTDIR=${pkgdir} install
+    install -Dm644 COPYING \
+        ${pkgdir}/usr/share/licenses/${pkgname}/COPYING
+    install -Dm644 docs/libcurl/libcurl.m4 \
+        ${pkgdir}/usr/share/aclocal/libcurl.m4
+    mv "${pkgdir}/usr/include/curl/curlbuild.h" "${pkgdir}/usr/include/curl/${_curlbuild}"
+    install -m 644 ${srcdir}/curlbuild.h "${pkgdir}/usr/include/curl/curlbuild.h"
+}
diff --git a/testing/curl/curlbuild.h b/testing/curl/curlbuild.h
new file mode 100644
index 000000000..b48862696
--- /dev/null
+++ b/testing/curl/curlbuild.h
@@ -0,0 +1,9 @@
+#include <bits/wordsize.h>
+
+#if __WORDSIZE == 32
+#include "curlbuild-32.h"
+#elif __WORDSIZE == 64
+#include "curlbuild-64.h"
+#else
+#error "Unknown word size"
+#endif
-- 
cgit v1.2.3-54-g00ecf