From abcf87c553a18aec8372de7f690b5aa91a7a0d24 Mon Sep 17 00:00:00 2001
From: root <root@rshg054.dnsready.net>
Date: Mon, 26 Sep 2011 23:14:33 +0000
Subject: Mon Sep 26 23:14:33 UTC 2011

---
 testing/curl/PKGBUILD    | 69 ++++++++++++++++++++++++++++++++++++++++++++++++
 testing/curl/curlbuild.h |  9 +++++++
 2 files changed, 78 insertions(+)
 create mode 100644 testing/curl/PKGBUILD
 create mode 100644 testing/curl/curlbuild.h

(limited to 'testing/curl')

diff --git a/testing/curl/PKGBUILD b/testing/curl/PKGBUILD
new file mode 100644
index 000000000..03214f302
--- /dev/null
+++ b/testing/curl/PKGBUILD
@@ -0,0 +1,69 @@
+# $Id: PKGBUILD 138498 2011-09-25 14:51:49Z dreisner $
+# Maintainer: Dave Reisner <dreisner@archlinux.org>
+# Contributor: Angel Velasquez <angvp@archlinux.org>
+# Contributor: Eric Belanger <eric@archlinux.org>
+# Contributor: Lucien Immink <l.immink@student.fnt.hvu.nl>
+# Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
+
+pkgname=curl
+pkgver=7.22.0
+pkgrel=2
+pkgdesc="An URL retrival utility and library"
+arch=('i686' 'x86_64')
+url="http://curl.haxx.se"
+license=('MIT')
+depends=('libssh2' 'openssl' 'zlib')
+makedepends=('perl-libwww')
+options=('!libtool')
+source=("http://curl.haxx.se/download/$pkgname-$pkgver.tar.gz"{,.asc}
+        curlbuild.h)
+md5sums=('e8c36126d21c893f085aca233906b5cc'
+         '1b061c348b63ea3e90c3f2c3af6a08d6'
+         '751bd433ede935c8fae727377625a8ae')
+
+ptrsize=$(cpp <<<'__SIZEOF_POINTER__' | sed '/^#/d')
+case $ptrsize in
+  8) _curlbuild=curlbuild-64.h ;;
+  4) _curlbuild=curlbuild-32.h ;;
+  *) error "unknown pointer size for architecture: %s bytes" "$ptrsize"
+    exit 1
+    ;;
+esac
+
+build() {
+  cd "$srcdir/$pkgname-$pkgver"
+
+  ./configure \
+      --prefix=/usr \
+      --mandir=/usr/share/man \
+      --disable-dependency-tracking \
+      --disable-ldap \
+      --disable-ldaps \
+      --enable-ipv6 \
+      --enable-manual \
+      --enable-versioned-symbols \
+      --enable-threaded-resolver \
+      --without-libidn \
+      --with-random=/dev/urandom \
+      --with-ca-bundle=/etc/ssl/certs/ca-bundle.crt
+  make
+
+  perl lib/mk-ca-bundle.pl
+}
+
+package() {
+  cd "$srcdir/$pkgname-$pkgver"
+
+  make DESTDIR="$pkgdir" install
+
+  # license
+  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
+
+  # cert bundle
+  install -Dm644 ca-bundle.crt "$pkgdir/etc/ssl/certs/ca-bundle.crt"
+
+  # devel
+  install -Dm644 docs/libcurl/libcurl.m4 "$pkgdir/usr/share/aclocal/libcurl.m4"
+  mv "$pkgdir/usr/include/curl/curlbuild.h" "$pkgdir/usr/include/curl/$_curlbuild"
+  install -m644 "$srcdir/curlbuild.h" "$pkgdir/usr/include/curl/curlbuild.h"
+}
diff --git a/testing/curl/curlbuild.h b/testing/curl/curlbuild.h
new file mode 100644
index 000000000..b48862696
--- /dev/null
+++ b/testing/curl/curlbuild.h
@@ -0,0 +1,9 @@
+#include <bits/wordsize.h>
+
+#if __WORDSIZE == 32
+#include "curlbuild-32.h"
+#elif __WORDSIZE == 64
+#include "curlbuild-64.h"
+#else
+#error "Unknown word size"
+#endif
-- 
cgit v1.2.3-54-g00ecf