From 59075f0265483f32e9ac4c67ba9e69cb019ba044 Mon Sep 17 00:00:00 2001
From: root <root@rshg047.dnsready.net>
Date: Fri, 8 Apr 2011 04:18:44 +0000
Subject: Fri Apr  8 04:18:44 UTC 2011

---
 testing/ekiga/PKGBUILD      | 38 ++++++++++++++++++++++++++++++++++++++
 testing/ekiga/ekiga.install | 22 ++++++++++++++++++++++
 2 files changed, 60 insertions(+)
 create mode 100644 testing/ekiga/PKGBUILD
 create mode 100644 testing/ekiga/ekiga.install

(limited to 'testing/ekiga')

diff --git a/testing/ekiga/PKGBUILD b/testing/ekiga/PKGBUILD
new file mode 100644
index 000000000..5bc0f6c4e
--- /dev/null
+++ b/testing/ekiga/PKGBUILD
@@ -0,0 +1,38 @@
+# $Id: PKGBUILD 112176 2011-03-04 10:45:51Z heftig $
+# Maintainer: Jan de Groot <jgc@archlinux.org>
+# Contributor: Tom K <tomk@runbox.com>
+
+pkgname=ekiga
+pkgver=3.3.0
+pkgrel=2
+pkgdesc="VOIP/Videoconferencing app with full SIP and H.323 support (GnomeMeeting expanded and renamed)"
+url="http://www.ekiga.org"
+license=(GPL)
+arch=(i686 x86_64)
+depends=('opal' 'boost-libs' 'libxv' 'libnotify' 'hicolor-icon-theme' 'avahi' 'gtk2')
+makedepends=('intltool' 'gnome-doc-utils' 'evolution-data-server' 'boost')
+optdepends=('evolution-data-server: Evolution integration')
+provides=('gnomemeeting')
+replaces=('gnomemeeting')
+options=(!emptydirs)
+groups=('gnome-extra')
+install=ekiga.install
+source=(http://ftp.gnome.org/pub/gnome/sources/${pkgname}/${pkgver%.*}/${pkgname}-${pkgver}.tar.bz2)
+sha256sums=('3fb22704e44afebf4294632505fb7a13f3eccb152fcb5878e97aa556d9486d2c')
+
+build() {
+  cd "${srcdir}/${pkgname}-${pkgver}"
+  ./configure --prefix=/usr --sysconfdir=/etc \
+      --localstatedir=/var --disable-schemas-install \
+      --disable-scrollkeeper --enable-dbus
+  make
+}
+
+package() {
+  cd "${srcdir}/${pkgname}-${pkgver}"
+  make DESTDIR="${pkgdir}" GCONF_DISABLE_MAKEFILE_SCHEMA_INSTALL=1 install
+
+  install -m755 -d "${pkgdir}/usr/share/gconf/schemas"
+  gconf-merge-schema "${pkgdir}/usr/share/gconf/schemas/${pkgname}.schemas" --domain ekiga ${pkgdir}/etc/gconf/schemas/*.schemas
+  rm -f ${pkgdir}/etc/gconf/schemas/*.schemas
+}
diff --git a/testing/ekiga/ekiga.install b/testing/ekiga/ekiga.install
new file mode 100644
index 000000000..b1d76a4a3
--- /dev/null
+++ b/testing/ekiga/ekiga.install
@@ -0,0 +1,22 @@
+pkgname=ekiga
+
+post_install() {
+  usr/sbin/gconfpkg --install ${pkgname}
+  gtk-update-icon-cache -q -t -f usr/share/icons/hicolor
+}
+
+pre_upgrade() {
+  pre_remove $1
+}
+
+post_upgrade() {
+  post_install $1
+}
+
+pre_remove() {
+  usr/sbin/gconfpkg --uninstall ${pkgname}
+}
+
+post_remove() {
+  gtk-update-icon-cache -q -t -f usr/share/icons/hicolor
+}
-- 
cgit v1.2.3-54-g00ecf