# $Id: PKGBUILD 69088 2012-04-09 09:04:50Z jelle $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Maintainer : Ionut Biru <ibiru@archlinux.org>
# Contributor: Joeny Ang <ang(dot)joeny(at)gmail(dot)com>

pkgname=shotwell
pkgver=0.12.1
pkgrel=1
pkgdesc="A digital photo organizer designed for the GNOME desktop environment"
arch=('i686' 'x86_64')
url="http://yorba.org/shotwell/"
license=('LGPL2.1')
depends=('glib2' 'gconf' 'libgee' 'libgphoto2' 'libunique3' 'libwebkit3' 'libgexiv2' 'libraw'
	 'librsvg' 'json-glib' 'desktop-file-utils' 'dconf' 'sqlite' 'gtk3' 'rest')
makedepends=('intltool' 'vala')
install=shotwell.install
source=("http://yorba.org/download/shotwell/0.12/shotwell-${pkgver}.tar.bz2")
md5sums=('af2fa1f6d9ee498c0e23c23d8bb9fc7b')

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  ./configure --prefix=/usr \
	--with-gconf-schema-file-dir=/usr/share/gconf/schemas \
	--disable-schemas-install \
	--disable-desktop-update \
	--disable-icon-update
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  rm -f $pkgdir/usr/share/glib-2.0/schemas/gschemas.compiled
}