# $Id: PKGBUILD 77306 2012-10-08 15:41:06Z spupykin $
# Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Shahar Weiss <sweiss4@gmx.net>

pkgname=torcs
pkgver=1.3.3
pkgrel=2
pkgdesc="A 3D racing cars simulator using OpenGL"
url="http://torcs.sourceforge.net"
license=("GPL")
arch=('i686' 'x86_64')
depends=('freeglut' 'libpng' 'freealut' 'libxi' 'libxmu' 'libxrandr' 'libvorbis' 'glu')
makedepends=('plib')
options=('!makeflags')
source=(http://downloads.sourceforge.net/sourceforge/$pkgname/$pkgname-${pkgver/_/-}.tar.bz2
        torcs.desktop
        torcs-gcc.patch)
md5sums=('0319c996dac4480f1182c03d2331b14a'
         '328e419e9f985c3e7b69924fe299330d'
         '5ae7e903df37300d3b8744328c756bff')

build() {
  cd $srcdir/$pkgname-${pkgver/_/-}
  unset LDFLAGS
  ./configure --prefix=/usr --x-includes=/usr/include --x-libraries=/usr/lib
  make
}

package() {
  depends=(${depends[@]} "torcs-data=$pkgver")
  cd $srcdir/$pkgname-${pkgver/_/-}
  make DESTDIR=${pkgdir} install
  install -D -m644 Ticon.png ${pkgdir}/usr/share/pixmaps/torcs.png
  install -D -m644 ../torcs.desktop ${pkgdir}/usr/share/applications/torcs.desktop
  find ${pkgdir} -type d -exec chmod 755 {} \;
}